IZBORNIK HOME FORUM ACCESS 2003 EXCEL 2003 WORD 2003  .
   
   
HOME
FORUM Win Tips&Tricks
   
KAKO INSTALIRATI
WINDOWS XP ?
Kako instalirati Win XP sa USB STICKA
Kako instalirati WINDOWS 7 ?
Naučite za 15 minuta raditi u Windows XP
Naučite Internet Explorer i Outlook Express
za 15 minuta
Kako kreirati BOOT CD za instalaciju Win95
   
MS OFFICE 2003
MS OFFICE 2007
   
   
HOME NETWORK
tutorijal za mreže
Network Windows 7 - XP
   
ZANIMLJIVI LINKOVI
BROJEVNI SUSTAVI
(DEC, OKT, BIN, HEX )
CMD - Command Prompt
CISCO - CCNA tutoriali
VLSM and SUBNETTING
   
Tutorijali za phpBB forum
JAVASCRIPT
VISUAL BASIC 6.0
AUTOCAD 2007
 

Adsense sponzor



MICROSOFT EXCEL 2007 - Kako prikazati vrijednost u zadnjoj ćeliji u stupcu (koloni) ili redu

Kako prikazati podatak iz posljednje popunjene ćelije
(Get last value from Column or Row)

Search This Web Site

Adsense sponzor




Formule za vraćanje podatka iz posljednje popunjene ćelije iz određenog stupca

U ovom tutorijalu prikazat ću nekoliko formula koje kao rezultat vraćaju podatak iz posljednje (zadnje) ćelije bilo u određenom stupcu ili redu.
NAPOMENA:
Kod referenciranja cijelog stupca osim A1:A65526 (A1:A1048576 za Excel 2007)  možete koristiti i A:A referenciranje pogotovo za one koji koriste Excel 2007, ili ograničiti do određenog reda A1:A1000.

Za početak evo formule koja vraća podatak iz posljednje popunjene ćeliju u stupcu A, bilo da je riječ o tekstu ili brojevnoj vrijednosti. Ne smetaju joj prazne ćelije (koje provjerava) između podataka u stupcu

=LOOKUP(2;1/(1-ISBLANK(A1:A65526));A1:A65526)
=LOOKUP(2;1/(1-ISBLANK(A1:A1000));A1:A1000)
=LOOKUP(2;1/(1-ISBLANK(A:A));A:A)


Formula slična prethodnoj koja vraća podatak iz posljednje popunjene ćelije u stupcu A

=LOOKUP(2;1/(A1:A65535<>"");A1:A65535)
=LOOKUP(2;1/(A:A<>"");A:A)


Get Last value from column

Slijedeća formula je ARRAY formula a vraća tekstualni ili brojevni podatak iz stupca A. Ne smetaju joj prazne ćelije između. Obavezno formulu završiti sa CTRL+SHIFT+ENTER

=INDEX(A:A;MAX(IF(ISBLANK(A1:A65535);0;ROW(A1:A65535))))
=INDEX(A:A;MAX(IF(ISBLANK(A:A);0;ROW(A:A))))


Slijedeća formula vraća podatak iz posljednje ispunjene ćelije ali uz uvjet. Formula daje dva rezultata što ovisi o popunjenosti svih ćelija u stupcu A. Ako postoji ćelija koja je prazna (blank) tada formula vraća posljednju ćeliju koja sadrži brojevnu vrijednost. Ako u stupcu nema praznih ćelija tada formula vraća podatak iz posljednje popunjene ćelije bilo da je tekst ili brojevna vrijednost

=OFFSET($A$1;COUNTA(A:A)-1;0)


Formula koja vraća podatak iz posljednje popunjene ćelije. Formula u obzir uzima samo brojevne vrijednosti a tekst ignorira

=LOOKUP(9,99999999999999E+307;A:A)


Slijedeća formula je ARRAY formula a vraća broj kao podatak iz stupca A. Ne smetaju joj prazne ćelije između. Obavezno formulu završiti sa CTRL+SHIFT+ENTER

Formula vraća podatak iz posljednje popunjene ćelije. Formula u obzir uzima samo brojevne vrijednosti a tekst ignorira. Ne smetaju joj prazne ćelije.

=INDEX(A:A;MAX(IF(ISNUMBER(A1:A65535);ROW(A1:A65535))))
=INDEX(A:A;MAX(IF(ISNUMBER(A:A);ROW(A:A))))


Formula vraća podatak iz posljednje popunjene ćelije. Formula u obzir uzima samo brojevne vrijednosti a tekst ignorira. Ne smetaju joj prazne ćelije.

=LOOKUP(MAX(A:A)+1;A:A)


Formula vraća podatak iz posljednje popunjene ćelije. Formula u obzir uzima samo tekst a brojeve ignorira. Ne smetaju joj prazne ćelije. [edit]: za korištenje naše abecede kao parametar koristite zadnje slovo "Ž"

=INDEX(A:A;MATCH(REPT("Ž";255);A:A))


Formule za vraćanje podatka ili vrijednosti iz posljednje popunjene ćelije u određenom redu
(Get last value from row)

Formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova ARRAY formula ignorira prazne ćelije ali i ćelije koje sadrže tekstni podatak. Formulu obavezno završiti sa CTRL+SHIFT+ENTER

=INDEX(1:1;1;MAX(IF(ISNUMBER(1:1);COLUMN(1:1))))

Get last value from row


Formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova ARRAY formula ignorira prazne ćelije ali i ćelije koje sadrže tekstni podatak. Formulu obavezno završiti sa CTRL+SHIFT+ENTER

=LOOKUP(9,99999999999999E+307;1:1)


Formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova ARRAY formula ignorira prazne ćelije ali i ćelije koje sadrže tekstni podatak. Formulu obavezno završiti sa CTRL+SHIFT+ENTER

=INDEX(1:1;MATCH(9,99999999999999E+307;1:1))


Formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova formula ignorira prazne ćelije ali i ćelije koje sadrže tekstni podatak.

=LOOKUP(MAX(1:1)+1;1:1)


Formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova formula ignorira prazne ćelije ali i ćelije koje sadrže brojevni podatak. Dakle vraća posljednju ćeliju koja sadrži tekst.
[edit]: za korištenje naše abecede kao parametar koristite zadnje slovo "Ž"

=INDEX(1:1;MATCH(REPT("Ž";255);1:1))




Formula koja vraća tekst kao zadnji podatak u redu. Ovisi o praznim ćelijama i popunjenosti ostalih ćelija pa stoga vodite računa koristeći ovu formulu

=OFFSET($A$1;0;COUNTA(1:1)-1)


Ova ARRAY formula je formula koja vraća podatak iz zadnje popunjene ćelije u određenom redu. Ova formula ignorira prazne ćelije a radi sa brojevnom vrijednošću i sa tekstnim podatkom. Obavezno formulu završiti sa CTRL+SHIFT+ENTER

=INDEX(1:1;1;MAX(IF(ISBLANK(1:1);0;COLUMN(1:1))))
=INDEX(7:7;1;MAX(IF(ISBLANK(7:7);0;COLUMN(7:7))))


Formula koja vraća zadnji podatak u redu. Ova formula radi sa brojevima i tekstom

=LOOKUP(2;1/(1-ISBLANK(1:1));1:1)

Adsense sponzor




Tutorijal: Kako kopirati i grupirati zadnje četiri ili pet posljednjih vrijednosti iz raspona podataka koji sadrži prazne među-ćelije kao rezultat neke formule


Formula koja vraća zadnji podatak u redu. Ova formula radi sa brojevima i tekstom

=LOOKUP(2;1/(1:1<>"");1:1)
=LOOKUP(2;1/(7:7<>"");7:7)

Adsense sponzor




NAPOMENA: Kod referenciranja cijelog stupca osim A1:A65526 (A1:A1048576 za Excel 2007)  možete koristiti i A:A referenciranje pogotovo za one koji koriste Excel 2007, ili ograničiti do određenog reda A1:A1000.

Pogledajte i ovaj tutorijal o Kopiranju bez praznih ćelija
Tutorijal sa raznim primjerima o kopiranju range ili nesusjednih ćelija bez praznih ćelija
Još jedan tutorijal o kopiranju bez praznih redova:
  Kako kopirati SELEKTIRANE ĆELIJE bez praznog reda      
Također pogledajte tutorijal: Kako kopirati više izabranih (ne susjednih) ćelija na drugi Sheet u vodoravnom rasporedu
Također pogledajte tutorijal: Automatsko kopiranje, grupiranje i zbrajanje prilikom unosa podataka

Također pogledajte link Display last entered data - Prikaz zadnjeg unesenog podatka





©- 2006 - 2018 - IvanC  - Sva prava pridržana.  ic.ims.hr