logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali - Zbrajanje vrijednosti iz jednog stupca ako postoje višestruki uvjeti

Vrati zbroj iz jednog stupca za višestruke uvjete




sponzor



Zbrajanje vrijednosti u jednom stupcu za više uvjeta

Ako ste ikada imali potrebu zbrajati vrijednosti u jednom stupcu koji sadrži višestruke kriterije, u ovom Excel tutorialu prikazati ću primjere kako možemo zbrojiti vrijednosti iz jednog stupca za više kriterija. Ako pogledate sliku ispod situacija je slijedeće.
U stupcima 'B' i 'D' uočite tekst koji želimo zbrojiti vrijednosti iz jednog stupca a to su stupci 'C' i 'E'. Također uočite da se u stupcima 'B' i 'D' nalaze se duplikati teksta. Naš zadatak je zbrojiti vrijednosti za uvjete teksta 'slovo A' i 'slovo M'.

tablica sa dva stupca i zbrajanje iz jednog stupca ako postoji više uvjeta

Formule ispod koristite za zbroj vrijednosti sa više uvjeta u jednom stupcu. Uočite da su kriteriji ili uvjeti definirani u samoj formuli.

Da bi zbrojili vrijednosti iz stupca 'C' (Header2) za kriterij dva slova 'A i M' tada možemo koristiti formulu
=SUM(SUMIF(B3:B6;{"A";"M"};C3:C6))

Da bi zbrojili vrijednosti iz stupca 'E' (Header4) za kriterij dva slova 'A i M' tada možemo koristiti formulu
=SUM(SUMIF(D3:D6;{"A";"M"};E3:E6))

Zbroj vrijednosti za jedinstvene iz dva stupca uz višestruke uvjete

Ako želimo pronaći jedinstvene tekstualne podatke iz dva stupca i zbrojiti vrijednosti iz jednog stupca tada to možemo na slijedeći način.

U stupcu 'G' na slici ispod uočite jedinstvene podatke iz dva stupca. Ove podatke možemo dobiti iz stupaca 'B i D' slijedećom formulom ispod slike.

Izdvajanje jedinstvenih podataka iz dva stupca

Vrati jedinstvene podatke ako postoje duplikati u dva stupca

Array formula prikazana ispod, nalazi se u ćeliji 'G3' i ona je slijedeća. (Ova formula vrati će 'A i M' dva jedinstvena slova jer se oni ponavljaju u oba 'B i D' stupca).

=IFERROR(INDEX(D:D;SMALL(IF(ISNUMBER(MATCH(D$3:D$6;B$3:B$6;0));ROW(D$3:D$6));ROWS(G$3:G3)));"")

Slijedeća formula u 'H3' ćeliji
Ova formula vratit će vrijednost iz istog reda za uvjet u 'G3' ćeliji. Formulu kopirajte dolje.

=SUMIF($D$3:$D$6;G3;$E$3:$E$6)

U 'H8' ćeliji imamo jednostavnu formulu za zbrajanje (SUM)

=SUM(H3:H7)

Formula u 'G13' ćeliji je slijedeća: (Još jedna formula koja je vezana za raspon ćelija 'G3:G7')
=SUMPRODUCT(C3:C6;--ISNUMBER(MATCH(B3:B6;$G$3:$G$7;0)))


Zbroj vrijednosti za višestruke uvjete iz jednog stupca

U slučaju da u određenim ćelijama definirate uvjete ili kriterije (u ovom slučaju na slici ispod to su 'J3' i 'M3' ćelije, tada možete koristiti formule ispod slike. (Sve formule ispod prikazane, vraćaju isti rezultat).

Zbroj vrijednosti za višestruke uvjete iz jednog stupca

Formula u 'L5' ćeliji je slijedeća:
=SUMPRODUCT((J3=B3:B6)*(C3:C6)+(K3=B3:B6)*(C3:C6))

Formula u 'L7' ćeliji je slijedeća:
=SUMPRODUCT(((B3:B6=J3)+(B3:B6=K3));C3:C6)

Formula u 'L9' ćeliji je slijedeća:
=SUMPRODUCT((B3:B6=J3)*(C3:C6))+SUMPRODUCT((B3:B6=K3)*(C3:C6))

Formula u 'L11' ćeliji je slijedeća:
=SUMPRODUCT(C3:C6;--ISNUMBER(MATCH(B3:B6;$J$3:$K$3;0)))

Formula u 'L15' ćeliji je slijedeća:
=SUMIF($B$3:$B$6;J$3;$C$3:$C$6)+SUMIF($B$3:$B$6;K$3;$C$3:$C$6)

Formula u 'L17' ćeliji je slijedeća: (ovdje obratite pažnju da ova formula ima tri uvjeta. Treći uvjet je 'Header2' koji se nalazi u 'L2' ćeliji.
=SUMIF($B$3:$B$6;J$3;INDEX($C$3:$C$6;0;MATCH(L$2;C2:E2;0)))+
SUMIF($B$3:$B$6;K$3;INDEX($C$3:$C$6;0;MATCH($L2;$C2:$E2;0)))

Zbroj vrijednosti za jedinstvene podatke duplikata uz kriterij <>0

U slučaju da imate situaciju kada želite postaviti uvjet ili kriterij tada možete koristiti pomoćne stupce kao na slici ispod.

zbroj vrijednosti za jedinstvene podatke duplikata iz dva stupca ako je kriterij nula

U stupcu 'F' na slici iznad nalaze se pomoćni podaci za stupac 'Header1'. U stupcu 'G' na slici iznad nalaze se pomoćni podaci za stupac 'Header3'. Uočite da na popisu u stupcu 'F' nema 'slova A'. Ako se pitate zašto? Zato jer je vrijednost za taj podatak u stupcu 'B' =0. a to je uvjet koji smo postavili u formuli.

Formula u 'F2' ćeliji je slijedeća:
=IF(VLOOKUP($A2;$A$2:$B$5;2;FALSE)=0;"";A2)

Formula u 'G2' ćeliji je slijedeća:
=IF(VLOOKUP($C2;$C$2:$D$5;2;FALSE)=0;"";C2)

U stupcu 'H' izdvojeni su jedinstveni podaci za duplikate iz stupaca 'A' i 'C' ali samo oni koji nemaju pripadajuću vrijednost nula '0'.

ARRAY CSE Formula u 'H2' ćeliji je slijedeća:
=IFERROR(INDEX(G:G;SMALL(IF(ISNUMBER(MATCH(G$2:G$5;F$2:F$5;0));ROW(G$2:G$5));ROWS(H$2:H2)));"")

I na kraju Array CSE formula u 'H8' ćeliji je slijedeća:
=SUMPRODUCT(D2:D5;--ISNUMBER(MATCH(C2:C5;H2:H5;0)))

Obratite pažnju kod korištenja Excel funkcije SUMPRODUCT. Ako imate puno redova i podataka ili ako imate puno formula koje sadrže Sumproduct funkciju, tada vam to može usporiti Excel prilikom izračuna.

Također možete koristiti i ove dvije ARRAY formule za koje nisu potrebni pomoćni stupci a time izbjegavate Sumproduct formulu.

=SUM(IF(COUNTIF(A2:A5;C2:C5)=1;D2:D5);0)-SUM(IF(COUNTIF(A2:A5;C2:C5)=1;IF(SUMIF(A2:A5;C2:C5;B2:B5)=0;D2:D5;0);0))
ili
=SUM(IF(COUNTIF(A2:A5;C2:C5)=1;IF(SUMIF(A2:A5;C2:C5;B2:B5)>0;D2:D5;0);0))




     

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela