logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali - Zbrajanje vrijednosti dijagonalno ili u koso prema dolje u Excelu, Kako zbrojiti sve brojeve dijagonalno prema gore, Dijagonalno zbrajanje vrijednosti u rasponu ćelija

Dijagonalno zbrajanje u Excelu,
Zbrajanje vrijednosti dijagonalno ili u koso u Excelu




sponzor



Kako zbrojiti vrijednosti dijagonalno prema dolje

Ako ste ikada imali potrebu zbrajati vrijednosti ili brojeve u koso ili dijagonalno u nekom rasponu ćelija a niste znali, tada je ovo tutorijal sa primjerima formula baš za vas. Kod kreiranja formula imajte na umu kada ćete upotrijebiti apsolutnu adresu a kada relativnu adresu raspona ćelija.

Excel primjer 1

Na slici ispod uočite određeni raspon ćelija koje sadrže vrijednosti ili brojeve. Za ovaj prvi primjer uočite u kojem rasponu ćelija nalaze se vrijednosti. Dakle prva lijeva gornja ćelija nalazi se na adresi 'A1'. Ovo je važno jer je ova ćelija 'A1' polazna točka za dijagonalno zbrajanje što možete uočiti u formulama koje se nalaze u prvom primjeru. U ovom prvom primjeru zbrajamo dijagonalne vrijednosti prema dolje od prve ćelije u koso desno (crveni brojevi na slici ispod)

Kako zbrojiti vrijednosti dijagonalno dolje u Excelu

Formule prikazane ispod vezane su za situaciju raspona ćelija na slici iznad. U koliko postavite neku od formula i poslije dodate redak ili stupac ispred trenutne pozicije raspona ćelija (Range) neke od formula prikazane ispod promijenit će rezultat. Dakle, vi trebate uzeti u obzir eventualne promjene pozicije raspona ćelija kao i koje vrijednosti želite zbrojiti dijagonalno. U odnosu na sliku iz ovog prvog primjera osnovna ARRAY formula dijagonalnog zbrajanja je slijedeća.

=SUM(IF(ROW(1:5)=COLUMN(A1:E5)-Cx;A1:E5))

U formuli iznad uočite važne argumente formule a to su 'ROW(1:5)' i 'Cx'.

  • ROW(1:5) => broj redaka u kojima se nalaze vrijednosti
  • Cx => broj stupaca u kojem se nalaze vrijednosti koje želimo dijagonalno zbrajati.

Ja ću ovdje pokazati više ARRAY formula koje vraćaju isti rezultat

  • =SUM(IF(ROW(1:5)=COLUMN(A1:E5)-0;A1:E5))
  • =SUM(IF(ROW(A1:E5)=COLUMN(A1:E5)-0;A1:E5;0))
  • =SUM(IF(ROW(INDIRECT(1&CHAR(58)&5))=COLUMN(A1:E5)-0;A1:E5))
  • =SUM(IF(ROW(A1:E5)=COLUMN(A1:E5)-(COLUMN($A$1)-1);A1:E5;0))
  • =SUM(IF(ROW(A1:E5)-MAX(ROW(A1:E5))=COLUMN(A1:E5)-MAX(COLUMN(A1:E5));A1:E5;FALSE))
  • =SUM(IF(ROW(INDIRECT(1&CHAR(58)&5))=COLUMN(A1:E5)-(COLUMN($A$1)-1);A1:E5))
  • =SUMPRODUCT((ROW($A$1:$E$5)-MAX(ROW(A1:E5))=COLUMN($A$1:$E$5)-MAX(COLUMN(A1:E5)))*($A$1:$E$5))

Postavite ove formule u vašu Workbook i probajte naknadno dodati nekoliko stupaca ili redova ispred trenutne situacije sa slike iz ovog prvog primjera. Uočite da neke formule mijenjaju rezultat u odnosu na prvobitno stanje. Zadnje tri formule sa popisa iznad, ne mijenjaju rezultat već su fiksirane.

Zadnju formulu iz popisa iznad možete kopirati u desnu stranu ili prema dolje. Tada će vam formula vratiti rezultate za svako slijedeće zbrajanje.

Kako u Excel tablici zbrojiti vrijednosti dijagonalno prema gore

Excel primjer 2

Na slici ispod uočite određeni raspon ćelija koje sadrže vrijednosti ili brojeve. Za ovaj drugi primjer uočite u kojem rasponu ćelija nalaze se vrijednosti. Dakle prva lijeva gornja ćelija nalazi se na adresi 'A1'.
S obzirom da mi želimo zbrajati u koso prema gore tada nam je startna ćelija 'A5'. Ovo je važno jer je ova ćelija 'A5' polazna točka za dijagonalno zbrajanje što možete uočiti u formulama koje se nalaze u drugom primjeru. U ovom drugom primjeru zbrajamo vrijednosti dijagonalno prema gore od zadnje ćelije u prvom stupcu do prve ćelije posljednjeg stupca u rasponu. (plavi brojevi na slici ispod)

Kako zbrojiti vrijednosti dijagonalno prema gore u Excelu

Vidi sliku iznad i osnovnu ARRAY formulu dijagonalnog zbrajanja prema gore desno prikazana je ispod.
Uočite dva važna argumenta u formuli (Rx i Cx).

=SUM(A1:E5*((ROWS(A1:E5)+Rx)-ROW(A1:E5)=COLUMN(A1:E5)-Cx))

  • Rx => broj redaka ispred bazne ćelije raspona podataka
  • Cx => broj stupaca ispred bazne ćelije raspona podataka

Formule mogu biti kreirane kao što je prikazano ispod

  • =SUM(A1:E5*((ROWS(A1:E5)+1)-ROW(A1:E5)=COLUMN(A1:E5)))
  • =SUM(A1:E5*((ROWS(A1:E5)+ROW(A1))-ROW(A1:E5)=COLUMN(A1:E5)))
  • =SUM(A1:E5*((ROWS(A1:E5)+COLUMN(A1))-ROW(A1:E5)=COLUMN(A1:E5)))
  • =SUM(A1:E5*((ROWS(A1:E5)+(ROW($A$1)-2))-ROW(A1:E5)=COLUMN(A1:E5)-COLUMN(A1)-1))
  • =SUMPRODUCT((ROW($A$1:$E$5)-MIN(ROW(A5:E7))=MIN(COLUMN(A5:E7))-COLUMN($A$1:$E$5))*($A$1:$E$5))

Ako za Rx postavite nulu (0) tada će formula zbrojiti ćelije 'A4','B3','C2' i 'D1' (na slici iznad vrijednosti označene crvenom bojom). Druga formula u popisu ispod nema problema s postavljanjem nule (0) za broj redaka ispred.

na primjer:

  • =SUM(A1:E5*((ROWS(A1:E5)+0)-ROW(A1:E5)=COLUMN(A1:E5)))
  • =SUMPRODUCT((ROW($A$1:$E$5)-MIN(ROW(A4:E6))=MIN(COLUMN(A4:E6))-COLUMN($A$1:$E$5))*($A$1:$E$5))

Uočite da u drugoj po redu formuli na popisu iznad prva startna ćelija je 'A4'. Dakle u ovom slučaju zbrajamo dijagonalno vrijednosti u Excel ćelijama počevši od 'A4','B3','C2' i 'D1' (na slici iznad vrijednosti označene crvenom bojom) vidi sliku ispod.

Rezultati dijagonalnog zbrajanja vrijednosti sa slike iznad prema gore

Dva retka ispred i tri stupca ispred raspona ćelija odnose se na sliku iznad tj. podatke iz tablice u kojoj želimo zbrojiti dijagonalne vrijednosti prema gore.

Rezultati dijagonalnog zbrajanja brojeva u koso prema gore

Da bi ste shvatili i razumjeli kako funkcioniraju navedene formule iznad učinite slijedeće.
Kreirajte tablicu vrijednosti u vašoj Excel radnoj knjizi (identičnu kao na prvoj slici Primjer 2.) i unesite dotične formule. Poslije dodajte nekoliko redaka i nekoliko stupaca ispred definiranog raspona ćelija. Uočite kako se rezultati mijenjaju zavisno od broja dodanih redaka i stupaca. Posljednje dvije formule od pet navedenih na popisu iznad neće promijeniti rezultat.

Dijagonalno zbrajanje vrijednosti u Excel tablici ako je broj stupaca i redaka isti

Excel primjer 3

U slučaju kada imate isti broj stupaca i redaka u rasponu ćelija tada imamo situaciju koja je opisana kao u prva dva primjera. U ovom trećem primjeru situacija je slična, ali različit broj stupaca i redaka ispred raspona ćelija.
Pogledajte sliku ispod!
Uočite jedan (1) stupac i dva (2) reda ispred raspona ćelija koje sadrže vrijednosti. Dakle imamo dodan određen broj stupaca ili redaka (Header Row i Header Column). Prva startna ćelija naše baze podataka je ćelija 'B3' kada zbrajamo dijagonalno prema dolje. Ako zbrajamo dijagonalno prema gore tada je prva startna ćelija 'B7'.

Koso zbrajanje u Excelu

Zbrajanje dijagonalnih ćelija u koso DOLJE silazno (na slici iznad označeno crvenom bojom, smeđa strelica)

U slučaju kada imamo određen broj redaka i stupaca ispred raspona ćelija, formule za dijagonalno zbrajanje prema DOLJE (silazno) mogu biti slijedeće.

Osnovna ARRAY formula za dijagonalno zbrajanje u koso prema 'dolje' je slijedeća

=SUM(B3:F7*((ROW(B3:F7)-Rx)=(COLUMN(B3:F7)-Cx)))

Ostale formule koje možete koristiti u ovom trećem primjeru za dijagonalno zbrajanje prema dolje silazno su slijedeće:

  • =SUM(B3:F7*(ROW(B3:F7)=COLUMN(B3:F7)+1))
  • =SUM(B3:F7*((ROW(B3:F7)-1)=(COLUMN(B3:F7)-0)))
  • =SUM(B3:F7*(ROW(B3:F7)=(COLUMN(B3:F7)-(1-2))))
  • =SUM(B3:F7*(ROW(B3:F7)=COLUMN(B3:F7)+(2-(COLUMN($A$1)))))
  • =SUM(B3:F7*(ROW(INDIRECT(3&CHAR(58)&7))=COLUMN(B3:F7)+(2-(COLUMN($A$1)))))

Uočite, u popisu iznad sve formule pomoću kojih možete dijagonalno zbrojiti sve ćelije u koso prema dolje (vrijednosti označene crvenim fontom). Zadnja ARRAY formula na popisu iznad je fiksna i ona neće promijeniti rezultat ako dodate nekoliko stupaca ili nekoliko redaka ispred range.

Zbrajanje dijagonalnih ćelija u koso GORE uzlazno (na slici iznad označeno plavom bojom, plava strelica)

U slučaju kada imamo određen broj redaka i stupaca ispred raspona ćelija, formule za dijagonalno zbrajanje prema GORE (uzlazno) mogu biti slijedeće.

Osnovna ARRAY formula za dijagonalno zbrajanje u koso prema 'gore' je slijedeća

=SUM(B3:F7*((ROW(B3:F7)+Rx)=(COLUMN(B3:F7)-Cx)))

Ostale formule koje možete koristiti u ovom trećem primjeru za dijagonalno zbrajanje prema gore uzlazno su slijedeće:

  • =SUM(B3:F7*(ROWS(B3:F7)+1-ROW(B3:F7)=COLUMN(B3:F7)-3))
  • =SUM(B3:F7*(ROWS(B3:F7)+2-ROW(B3:F7)=COLUMN(B3:F7)-2))
  • =SUM(B3:F7*((ROWS(B3:F7)+(ROW($A$2)-1))-ROW(B3:F7)=COLUMN(B3:F7)-COLUMN(C3)-0))

Uočite, u popisu iznad sve formule pomoću kojih možete dijagonalno zbrojiti sve ćelije u koso prema gore (vrijednosti označene plavim fontom). Zadnja ARRAY formula na popisu iznad je fiksna i ona neće promijeniti rezultat ako dodate nekoliko stupaca ili nekoliko redaka ispred range.


Dijagonalno zbrajanje vrijednosti u Excel tablici ako je broj stupaca i redaka različit

Excel primjer 4

U slučaju kada imate različiti broj stupaca i redaka (u ovom primjeru 6 redaka i 5 stupaca) u rasponu ćelija tada imamo situaciju koja je opisana u nastavku tutorijala. U ovom četvrtom primjeru imamo različit broj stupaca i redaka raspona ćelija kao i to ispred raspona ćelija imamo 1 stupac i 2 retka.
Pogledajte sliku ispod!
Uočite jedan (1) stupac i dva (2) reda ispred raspona ćelija koje sadrže vrijednosti. Dakle imamo dodan određen broj stupaca ili redaka (6 Header Row Data i 5 Header Column Data). Prva startna ćelija naše baze podataka je ćelija 'B3' kada zbrajamo dijagonalno prema dolje. Ako zbrajamo dijagonalno prema dolje tada je prva startna ćelija 'A3'.

Dijagonalno zbrajanje brojeva u tablici Excela

Zbrajanje dijagonalnih vrijednosti po stupcu

Ako želimo krenuti od početka i zbrojiti brojeve ili vrijednosti dijagonalno po stupcu startavši od ćelije 'B3' tada je osnovna formula slijedeća. U formuli ispod uočite broj redaka označen zeleno i broj stupaca označen plavo/crveno.

  • =SUMPRODUCT(((MATCH($A$3:$A$8;$A$3:$A$8;0)-MATCH($B$2:$F$2;$B$2:$F$2;0))=5-1)*($B$3:$F$8))
  • =SUMPRODUCT((((ROW($A$3:$A$8)-2)-(COLUMN($B$2:$F$2)-1))=5-1)*($B$3:$F$8))

Slijedeće formule ispod za dijagonalno zbrajanje daju isti rezultat

  • =SUMPRODUCT(((MATCH($A$3:$A$8;$A$3:$A$8;0)-MATCH($B$2:$F$2;$B$2:$F$2;0))=5-COLUMN(A1))*($B$3:$F$8))
  • =SUMPRODUCT(((MATCH($A$3:$A$8;$A$3:$A$8;0)-MATCH($B$2:$F$2;$B$2:$F$2;0))=COUNTA($B$2:$F$2)-COLUMN(A1))*($B$3:$F$8))
  • =SUMPRODUCT(((MATCH($A$3:$A$8;$A$3:$A$8;0)-MATCH($B$2:$F$2;$B$2:$F$2;0))=COUNTA($B$2:$F$2)-COUNTA($B2:B2))*($B$3:$F$8))
  • =SUMPRODUCT((((ROW($A$3:$A$8)-2)-(COLUMN($B$2:$F$2)-1))=5-COLUMN(A1))*($B$3:$F$8))
  • =SUMPRODUCT((((ROW($A$3:$A$8)-2)-(COLUMN($B$2:$F$2)-1))=COUNTA($B$2:$F$2)-COUNTA($B2:B2))*($B$3:$F$8))
  • =SUMPRODUCT((((ROW($A$3:$A$8)-ROW($B$2))-(COLUMN($B$2:$F$2)-COLUMN($A$1)))=COUNTA($B$2:$F$2)-COUNTA($B2:B2))*($B$3:$F$8))

Formula koja zbraja prema dolje (crvene vrijednosti) u ćeliji 'F11' je slijedeća. (ovu formulu kopirajte u lijevu stranu da bi dobili dijagonalni zbroj slijedećih ćelija u koso.

=SUMPRODUCT(((MATCH($A$3:$A$8;$A$3:$A$8;0)-MATCH($B$2:$F$2;$B$2:$F$2;0))=COUNTA($B$2:$F$2)-COUNTA($B2:F2))*($B$3:$F$8))

Dijagonalno zbrajanje u koso prema dolje za određen broj stupaca

Ako želite zbrajati vrijednosti koso ili dijagonalno prema dolje ali za specifičan broj stupaca tada koristite ovu ARRAY formulu ispod. Formula se nalazi u ćeliji 'I11' na slici iznad a specifičan broj stupaca kao uvjet 'broj 3' nalazi se u ćeliji 'H11' na slici iznad. Ova formula ispod dijagonalno zbraja vrijednosti samo za prva tri stupca u rasponu podataka.

=SUM(IF(ROW(OFFSET($B$3:$F$8;0;0;$H$11;H11))-MAX(ROW(OFFSET($B$3:$F$8;0;0;$H$11;$H$11)))=COLUMN(OFFSET($B$3:$F$8;0;0;$H$11;$H$11))-MAX(COLUMN(OFFSET($B$3:$F$8;0;0;$H$11;$H$11)));OFFSET($B$3:$F$8;0;0;$H$11;$H$11);FALSE))

Kopiranje formule za dijagonalno zbrajanje u Excelu

U koliko želite zbrojiti sve dijagonalne ćelije u Excel tablici ili Excel rasponu podataka tada iskoristite ovu formulu ispod.

=SUMPRODUCT((ROW($B$3:$F$8)-MAX(ROW(B2:F7))=COLUMN($B$3:$F$8)-MAX(COLUMN(B2:F7)))*($B$3:$F$8))

Ova formula kao rezultat vraća dijagonalni zbroj svih vrijednosti sa startom od ćelije 'B3' u koso prema dolje (vidi sliku ispod).
Ako formulu kopirate prema dolje tada ćete dobiti dijagonalni zbroj vrijednosti koje startaju od ćelije 'B4', 'B5','B6' itd.
Ako formulu kopirate u desnu stranu tada ćete dobiti dijagonalni zbroj vrijednosti koje startaju od ćelije 'C3', 'D3','E3' itd.

kopiranje-formula-za-dijagonalno-zbrajanje-u-excelu




     

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela