logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCE 2013 tutoriali - Unikati u Excelu, Unique in Excel, Kako kopirati unikatni tekst ili string iz stupca u Excelu, Kako izbrojiti koliko se puta pojavljuje određeni tekst u stupcu, Kako od duplikata teksta kreirati jedinstveni tekst ili string, Kako izbrojiti jedinstvene podatke i prikazati redoslijedne brojeve pojavljivanja, Kopiranje ćelija koje sadrže jedinstveni tekst u stupcu, Kako izbrojiti koliko se puta pojavljuje tekst u stupcu, Izdvajanje unikatnih tekstualnih podataka iz Excel stupca, Kopiranje i grupiranje Unique data iz stupca, Kopiranje i sortiranje jedinstvenih podataka iz stupca, Copy and sort Unique data from column, Kako kopirati unikatne vrijednosti ili brojeve iz stupca u Excelu, Kako kopirati jedinstvene podatke iz raspona ćelija ili Excel tablice, Copy unique data from range of Excel table

Kopiranje jedinstvenih vrijednosti ili podataka u Excelu, UNIQUE in Excel




sponzor



Kako kopirati unikatni tekst ili string iz stupca u Excelu

U ovom tutorijalu prikazati ću kako možemo za kopirati i grupirati jedinstvene (unikatne) vrijednosti, tekst ili string u Excelu. Ovaj tutorijal shvatite kao zbirku formula (ja nisam autor svih formula) pomoću koji izdvajamo unique podatke, tekst, vrijednosti ili brojeve, bilo da ih samo kopiramo u postojećem redoslijedu ili sortiramo uzlaznim redoslijedom (A-Z).

Na slici ispod uočite više stupaca. U svakom stupcu nalazi se formula za kopiranje unikatnih podataka ili prebrojavanje pojavljivanja određenog podataka u stupcu. U stupcu 'A' nalaze se podaci. Na prvoj slici uočite da je situacija kada imamo tekstualne podatke u stupcu A.

Kopiranje i grupiranje unikatnog teksta iz stupca u Excelu

Kako izbrojiti koliko se puta pojavljuje određeni tekst u stupcu

Formula u ćeliji 'B3' je slijedeća ispod. Ova formula izvršava brojanje određenog uvjeta a u ovom slučaju to je string ili tekstualni podatak 'IvanC'. Formulu kopirajte do zadnjeg retka.

=IF($A$3:$A$21="IvanC";COUNTIF(A$3:A3;A3);"")

Kako od duplikata teksta kreirati jedinstveni tekst ili string

Pretpostavljam da ponekada možete doći u situaciju kada od duplikata u nekom rasponu ćelija morate kreirati jedinstveni podatak (Unique data) da bi mogli nastaviti daljnje kalkulacije izračuna i postići željeni cilj.

Formula u ćeliji 'C3' je slijedeća ispod. Ova formula pretražuje stupac 'A' i postavljeni uvjet u formuli pridružuje serijski broj redoslijeda pojavljivanja uvjeta a u ovom slučaju to je string ili tekstualni podatak 'IvanC'. Formulu kopirajte do zadnjeg retka.

=IF(A3="IvanC";"IvanC"&COUNTIF(A$2:A3;"IvanC");"")

Kako izbrojiti jedinstvene podatke i prikazati redoslijedne brojeve pojavljivanja

Formula u ćeliji 'D3' je slijedeća ispod. Ova formula izvršava pretraživanje stupca 'A' i kao rezultat vraća broj pojavljivanja jedinstvenog podatka iz istog reda. U koliko formula naiđe na duplikat, ignorira ga i nastavlja dalje u slijedećem retku. Formulu kopirajte do zadnjeg retka.

=IF(COUNTIF(A$1:A3;A3)=1;MAX(D$1:D1)+1;"")

Kopiranje ćelija koje sadrže jedinstveni tekst u stupcu

Formula u ćeliji 'E2' je slijedeća ispod. Ova formula vrši brojanje jedinstvenih podataka/teksta u stupcu 'A'. Formula je preduvjet i vezana za formulu ispod u ćeliji E3.

=SUMPRODUCT(--ISTEXT(A$3:A$21);1/COUNTIF(A$3:A$21;A$3:A$21&""))

ARRAY formula u ćeliji 'E3' je slijedeća ispod. Ova formula kao rezultat vraća sve jedinstvene tekstualne podatke iz stupca 'A'. Formula je vezana za formulu u ćeliji E2. Formulu završite sa Ctrl+Shift+Enter. Formulu kopirajte do zadnjeg retka.

=IF(ROWS(E$3:E3)>E$2;"";INDEX(A$3:A$21;SMALL(IF(FREQUENCY(IF(ISTEXT(A$3:A$21);IF(A$3:A$21<>"";
MATCH(A$3:A$21;A$3:A$21;0)));ROW(A$3:A$21)-ROW(A$3)+1);ROW(A$3:A$21)-ROW(A$3)+1);ROWS(E$3:E3))))

Kako izbrojiti koliko se puta pojavljuje tekst u stupcu

Formula u ćeliji 'F3' je slijedeća ispod. Ova formula kao rezultat vraća broj pojavljivanja jedinstvenog tekstualnog podatka iz stupca 'A'. Formula je vezana za formulu u ćeliji E3 jer se u njoj nalazi uvjet. Formulu kopirajte do zadnjeg retka

=IF(OR(E3=0;E3="");"";COUNTIF($A$3:$A$21;E3))

Izdvajanje unikatnih tekstualnih podataka iz Excel stupca

ARRAY formula u ćeliji 'G3' je slijedeća ispod. Još jedna formula koja vraća unikatne tekstualne podatke iz stupca. Ova formula kao rezultat vraća sve jedinstvene podatke teksta iz stupca 'A', naravno kao što možete uočiti podaci su nesortirani. Formulu kopirajte do zadnjeg retka

=IFERROR(IF(INDEX($A$3:$A$21;MATCH(0;COUNTIF($G$2:G2;$A$3:$A$21 );0))=0;"";INDEX($A$3:$A$21;MATCH(0;COUNTIF($G$2:G2;$A$3:$A$21 );0)));"")

Kopiranje i grupiranje Unique data iz stupca

ARRAY formula u ćeliji 'H3' je slijedeća ispod. Još jedna formula koja vraća Unique nesortirane podatke iz stupca, naravno kao što možete uočiti podaci su nesortirani. Formulu kopirajte do zadnjeg retka

=IFERROR(INDEX($A$3:$A$21;SMALL(MATCH($A$3:$A$21;$A$3:$A$21;0);SUM((COUNTIF($A$3:$A$21;$H$2:H2)))+1));"")

Kopiranje i sortiranje jedinstvenih podataka iz stupca

U stupcu 'I' imamo dvije formule a druga formula zavisi od prve formule.

ARRAY formula u ćeliji 'I3' je slijedeća ispod. Formula kao rezultat vraća prvi jedinstveni podatak iz stupca 'A'.

=INDEX($A$3:$A$21;MATCH(0;COUNTIF($A$3:$A$21;"<"&$A$3:$A$21);0))

ARRAY formula u ćeliji 'I4' je slijedeća ispod. Formula kao rezultat nastavlja vraćati ostale jedinstvene podatke iz stupca 'A'. Formula je u zavisnosti sa formulom iznad u ćeliji I3. Formulu kopirajte do zadnjeg retka.

=IF(COUNTIF($A$3:$A$21;">"&I3);INDEX($A$3:$A$21;MATCH(COUNTIF($A$3:$A$21;"<="&I3);COUNTIF($A$3:
$A$21;"<"&$A$3:$A$21);0));"")

Copy and sort Unique data from column

Za razliku od prethodnog stupca u 'J' u kojem se nalaze dvije formule za vraćanje jedinstvenih podataka iz stupca 'A' u 'I' stupcu imamo samo jednu array formulu.

ARRAY formula u ćeliji 'J3' je slijedeća ispod. Formula kaorezultat prikazuje jedinstvene podatke iz stupca 'A'. Formulu kopirajte do zadnjeg retka.

=IFERROR(INDEX($A$3:$A$21;MATCH(0;COUNTIF($A$3:$A$21;"<"&$A$3:$A$21)-SUM(COUNTIF($A$3:$A$21;"="&J$2:J2));0));"")

Kako kopirati unikatne vrijednosti ili brojeve iz stupca u Excelu

Sve gore navedeno je vezano za tekstualne podatke. Ako imate situaciju kada su u pitanju brojevi ili vrijednosti tada iskoristite iste iznad formule. Na slici ispod uočite kako izgleda situacija koristeći iznad navedene formule ako 'A' stupac sadrži vrijednosti ili brojeve.

Kopiranje i grupiranje jedinstvenih brojeva ili vrijednosti iz stupca u Excelu

Formula u ćeliji 'C3' je slijedeća ispod. Ova formula vezana je za brojeve ili vrijednosti, pomoću ove formule možemo duplikate vrijednosti konvertirati u unikatne vrijednosti.

=IF(A3=77;A3&"-"&COUNTIF(A$2:A3;77);"")

Formule koje se nalaze u retku 22 su slijedeće:

ARRAY formula u ćelijama u 'A22', 'G22', 'H22' je slijedeća. Formula broji koliko ima unikatnih podataka u rasponu ćelija

=SUM(IF(FREQUENCY(IF(SUBTOTAL(3;OFFSET($A$3:$A$21;ROW($A$3:$A$21)-ROW($A$3);0;1));MATCH($A$3:$A$21;$A$3:$A$21;0));ROW($A$3:$A$21)-ROW($A$3)+1);1))

Formula u ćelijama 'B22', 'D22', 'F22', je slijedeća: Formula prebrojava koliko je popunjenih ćelija u stupcu

=COUNT(B3:B21)

Formula u ćelijama 'C22', 'E22', 'I22', 'J22' je slijedeća: Formula vraća koliko je popunjenih ćelija koje sadrže tekst u stupcu

=SUMPRODUCT(--ISTEXT(C$3:C$21);1/COUNTIF(C$3:C$21;C$3:C$21&""))-1

Kako kopirati jedinstvene podatke iz raspona ćelija ili Excel tablice

U situaciji kada imate tablicu ili raspon ćelija a imate potrebu kopirati ili izdvojiti jedinstvene podatke, evo nekoliko primjera, kako možete izdvojiti jedinstvene podatke iz tablice

U prvom primjeru na slici ispod, uočite da su sve ćelije u tablici popunjene. U koliko neka ćelija ne sadrži podatak tj. prazna je tada će formula kao rezultat vratiti broj nula (0).

ARRAY formula u ćeliji 'F2' je slijedeća: Formula vrši pretraživanje cijelog raspona ćelija tablice i vraća prvi jedinstveni podatak iz raspona. Formulu kopirajte do zadnjeg retka

=IFERROR(INDEX($A$2:$D$5;MIN(IF(COUNTIF($F$1:F1;$A$2:$D$5)=0;ROW($A$2:$D$5)-MIN(ROW($A$2:$D$5))+1));MATCH
(0;COUNTIF($F$1:F1;INDEX($A$2:$D$5;MIN(IF(COUNTIF($F$1:F1;$A$2:$D$5)=0;ROW($A$2:$D$5)-MIN(ROW($A$2:$D$5))+1));;1));0);1);"")

ARRAY formula u ćeliji 'G2' je slijedeća: Formula vrši pretraživanje raspona ćelija A2:D5 i vraća Unique podatke iz raspona. Uočite da je raspon ćelija u tablici imenovan nazivom "myrange" . Formula treba biti u jednoj liniji koda

=IFERROR(INDEX(myrange;SMALL(IF(SMALL(IF(COUNTIF($G$1:G1;myrange)=0;COUNTIF(myrange;"<"&myrange)+1;"");1)=
COUNTIF(myrange;"<"&myrange)+1;ROW(myrange)-MIN(ROW(myrange))+1);1);MATCH(MIN(IF(COUNTIF($G$1:G1;myrange)
>0;"";COUNTIF(myrange;"<"&myrange)+1));INDEX(COUNTIF(myrange;"<"&myrange)+1;SMALL(IF(SMALL(IF(COUNTIF(
$G$1:G1;myrange)=0;COUNTIF(myrange;"<"&myrange)+1;"");1)=COUNTIF(myrange;"<"&myrange)+1;ROW(myrange)
-MIN(ROW(myrange))+1);1);;1);0);1);"")

Izdvajanje jedinstvenih podataka iz Excel tablice

Copy unique data from range of Excel table

U ovom drugom primjeru na slici ispod uočite sličnu situaciju kao u prethodnom primjeru. Razlika je u tome što u rasponu ćelija Excel tablice neke ćelije su prazne i ne sadrže podatak.

ARRAY formula u ćeliji 'F2' je slijedeća ispod: Formula vrši pretraživanje raspona ćelija A2:D9 i kopira i grupira sve Unique data. Uočite ovaj dio formule ROW($2:$9) koji je vezan za broj redaka u tablici.

=INDIRECT(TEXT(MIN(IF(($A$2:$D$9<>"")*(COUNTIF($F$1:F1;$A$2:$D$9)=0);ROW($2:$9)*100+COLUMN($A:$D);
7^8));"R0C00");)&""

Kopiranje i grupiranje jedinstvenih podataka iz raspona ćelija Excel tablice

sponzor


Uz ovu temu pogledajte tutorijal Kopiranje i sortiranje Unique alfanumeričkih podataka u Excelu.




   

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela