logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali - Ugniježđene funkcije, Ugnježđivanje funkcije unutar funkcije, Kako kreirati formulu sa više Excel funkcija, Kako ugnijezditi funkciju unutar funkcije u Excelu, Izračun ugniježđene formule korak po korak, Kako brzo saznati koji je rezultat ugniježđene funkcije

Ugniježđene funkcije -
Kako kreirati formulu sa više Excel funkcija -
Ugnježđivanje funkcije unutar funkcije -
Izračun ugniježđene formule korak po korak




sponzor



Kako ugraditi formulu unutar formule ili kako ugnijezditi formulu u Excel formulu

Na samom početku ovog tutorijala želim prikazati jednostavno umetanje formule unutar Excel formule. Na slici ispod uočite u originalnom primjeru formule u tri ćelije A1, A2 i A3. Na dijelu slike koji je uokviren crvenim okvirom uočite jednu jedinu formulu u koju su ugrađene formule iz A2 i A1. Rezultat je isti u oba primjera. Na isti način ugrađujemo ili umećemo funkcije unutar funkcija ili formula.
Excel 97-2003 podržava 7 ugniježđenih funkcija a Excel 2007 i noviji podržavaju 64 ugniježđene funkcije.

Kako ugraditi formulu unutar Excel formule

Kako ugnijezditi jednu funkciju unutar druge funkcije u Excelu i napraviti formulu

Vjerujem da znate što je formula i kako se kreira u Excelu (pogledajte primjer iznad), ako ne znate pogledajte tutorijal na linku Formula u Excelu. U ovom primjeru tutorijala želim pokazati kako možete koristiti ugniježđene funkcije tj. ugraditi Excel MATCH funkciju unutar VLOOKUP funkcije.

U situaciji na slici ispod uočite zadatak koji moramo riješiti. U Excel ćeliji H1 tražimo rezultat iz raspona podataka A1:D6 na osnovu dva uvjeta koji se nalaze u ćelijama F2 i G2.

Umetanje funkcije unutar druge funkcije u Excelu

Ovaj problem pretraživanja i vraćanja sjecišta reda i stupca možemo riješiti funkcijom VLOOKUP. Vjerujem da znate sintaksu Excel funkcije Vlookup za pretraživanje raspona podataka.

Excel VLOOKUP funkcija

Funkcija Vlookup ima slijedeću sintaksu: VLOOKUP(lookup_value;table_array;col_index_num;range_lookup)
U sintaksi možemo vidjeti argumente funkcije koje je potrebno postaviti da bi funkcija vratila željeni rezultat. Argumente Excel funkcije možete vidjeti kada počinjete pisati formulu i ako želite tekstualno ispisati argumente funkcije pritisnite kombinaciju tipki CTRL+SHIFT+A nakon što upišete naziv funkcije i otvorenu zagradu. Opisani način izgleda kao na slici ispod.

Argumenti Excel funkcije Vlookup

Prvi argument: lookup_value je uvjet za kojega želimo vratiti određeni rezultat, u ovom slučaju pronaći red u kojem se nalazi uvjet i vratiti rezultat iz stupca za drugi uvjet ili kriterij
Drugi argument: table_array je raspon ćelija u kojima pretražujemo uvjete i rezultate a to je range A2:D6
Treći argument: col_index je broj stupca iz kojega trebamo rezultat a njega određuje drugi uvjet tj. naziv voća
Četvrti argument: range_lookup je logička vrijednost TRUE ili FALSE a zavisi da li želimo pronaći točnu vrijednost ili približnu vrijednost

Excel MATCH funkcija

Funkcija Match ima slijedeću sintaksu: MATCH(lookup_value;lookup_array;match_type)
U sintaksi ove funkcije uočite argumente funkcije koje je potrebno postaviti da bi funkcija vratila željeni rezultat. U ovom slučaju (to ćete kasnije vidjeti) ova funkcija kao rezultat vraća broj stupca. Da se ne bi zavarali, funkcija MATCH može vratiti i broj reda u jednom stupcu.

Prvi argument: lookup_value je uvjet za kojega želimo vratiti određeni rezultat, u ovom slučaju pronaći broj stupca za postavljeni uvjet ili kriterij
Drugi argument: table_array je raspon ćelija u kojima pretražujemo uvjete i rezultate, uočite da je to prvi red i nazivi u voća njemu
Treći argument: match_type je tip koji može biti -1, 0 i 1 (više o tiupovima na linku funkcija MATCH

Ugniježđenje funkcije MATCH unutar funkcije VLOOKUP

Sada kada sam pojasnio funkcije VLOOKUP i MATCH možemo krenuti na kreiranje formule sa Excel funkcijom unutar druge Excel funkcije. Rezultat u ćeliji za postavljene uvjete je vrijednost 110, Kako smo dobili ovaj rezultat?

Ugniježđena funkcije u drugoj funkciji i kreiranje formule sa više funkcija

Ako bi koristili samo jednu funkciju i to ciljano zbog toga što znamo rezultat formula bi izgledala ovako

=VLOOKUP(F2;$A$2:$D$6;3;0)

Dakle, znamo da nam je rezultat za uvjete 'Mark' i 'Plum' vrijednost 110 koja se nalazi u stupcu broj 3. VLOOKUP je prvi uvjet pronašao u Row 4 a drugi uvjet u stupcu broj 3 (Excel broji stupce s lijeva na desno; A, B, C, D itd. U ovom slučaju stupac C je treći stupac u nizu. Međutim, što bi se dogodilo da upišemo za drugi uvjet 'Apricot'. Formula u ovom obliku vratila bi isti rezultat kao i u prvom slučaju kod uvjeta 'Plum'. Zbog čega je to tako? Zato što nam u formulu treći argument i dalje je broj 3 tj. broj stupca.

Da bi izbjegli ovakve probleme potrebno je automatizirati ovaj broj stupca s obzirom na uvjet 2. To ćemo riješiti funkcijom MATCH. Excel funkcija Match vratiti će nam automatski broj stupca s obzirom na postavljeni uvjet 2.

sponzor


Kako funkcionira funkcija Match u ovom slučaju. Sami tok proračuna funkcije korak po korak možete vidjeti korištenjem naredbe Evaluate Formula u grupi naredbi Auditing na alatnoj traci Formulas. Dakle, funkcija MATCH vraća kao rezultat redni broj stupca iz zadanog raspona podataka a u ovom slučaju to je range u prvom redu A1:D1.

=MATCH(G2;$A$1:$D$1;0)

Iz formule uočavamo da funkcija Match uvjet 2 u ćeliji F2 traži u rasponu podataka A1:D1. Kada pronađe identičnu vrijednost (koju označava argument 'match_type') vratiti će broj stupca u kojem se nalazi identična vrijednost. U ovom slučaju to je podatak iz stupca broj 3 u prvom redu. Kada bi za uvjet 2 postavili naziv voća 'Apricot' tada bi ova formula i funkcija vratila kao rezultat stupac broj 4 jer se u njemu nalazi identična vrijednost-podatak uvjetu 2.

Sada dolazimo do ključnog rješenja tj. kako ugnijezditi Excel funkciju MATCH unutar Excel funkcije VLOOKUP. Nadam se da ste shvatili da treći argument funkcije VLOOKUP je broj stupca. S obzirom da funkcija MATCH kao rezultat vraća broj stupca, umjesto broja unutar funkcije VLOOKUP za treći argument (col_index_num) možemo postaviti funkciju MATCH.

I na kraju formula izgleda ovako: =VLOOKUP(F2;$A$2:$D$6;MATCH(G2;$A$1:$D$1;0);0)
Ako imenujete raspone podataka tada formula može izgledati ovako: =VLOOKUP(F2;data;MATCH(G2;fruits;0);0)

Kombiniranje funkcija INDEX i MATCH

Ovaj zadatak može se riješiti i kombiniranjem drugih funkcija kao npr. ove formule ispod.

=INDEX($B$2:$D$6;MATCH(F2;$A$2:$A$6;0);MATCH(G2;$B$1:$D$1;0))

Prva funkcija MATCH u formuli iznad vraća broj 3 za uvjet1 u stupcu A2:A6. U ovom slučaju Row4 je treći red u nizu raspona podataka.
Druga funkcija MATCH vraća broj 2 za uvjet2 koji označava broj stupca za range B1:D1. U ovom slučaju stupac C je drugi stupac u nizu.
I na kraju funkcija INDEX koja ima sintaxu =INDEX(array;row_num;column_num) pronalazi sjecište reda 3 i stupca 2 za raspon podataka B2:D6

Kombiniranje funkcija OFFSET i MATCH

Još jedna formula koja vraća isti rezultata ali sa drugačijom kombinacijom ugniježđene funkcije OFFSET i MATCH.

=OFFSET($A$1;MATCH(F2;$A$2:$A$6;0);MATCH(G2;$B$1:$D$1;0))

Dakle formula iznad vraća isti rezultat kao i sve gornje formule ali tako što OFFSET funkcija računa odmake od navedenog prvog argumenta. Ovu formulu za istraživanje ostavljam vama, kao i ovu HLOOKUP formulu ispod koja vraća isti rezultat.

=HLOOKUP(G2;$A$1:$D$6;MATCH(F2;$A$2:$A$6)+1;FALSE)

Izračun ugniježđene formule korak po korak

Pomoću naredbe Evaluate formula možete pogledati shvatiti kako Excel izvršava proračun neke formule a time i funkcije, uradite slijedeće:

  • Na Formulas alatnoj traci u grupi Formula Auditing kliknite na Evaluate Formula i pratite korak po korak klikom na Evaluate button.
  • Ako vam je Excel na Hrvatskom jeziku tada uradite slijedeće: Na alatnoj traci Formule kliknite u grupi Nadzor Formula na naredbu Vrednovanje Formule.
  • Ili ako imate Excel sa drugačijim prijevodom naredbi tada uradite slijedeće: Na alatnoj traci Formule kliknite u grupi Kontrola Formule na naredbu Analiziraj Formulu.

Kako brzo saznati koji je rezultat ugniježđene funkcije

Osim "Evaluate formula" ako želite, u formula baru možete saznati rezultat Excel funkcije koju ste ugnijezdili unutar neke druge Excel funkcije. U ovom primjeru pokazati ću kako brzo možete saznati rezultat MATCH funkcije koja je ugniježđena u VLOOKUP funkciju a da ne morate pregledavati Evaluate Formula.

Na slici ispod pogledajte situaciju u kojoj sam ugnijezdio Excel MATCH funkciju unutar Excel VLOOKUP funkcije. Da bi brzo vidjeli rezultat MATCH funkcije učinite slijedeće

  1. Selektirajte ćeliju koja sadrži formulu sa ugniježđenom funkcijom
  2. U polju za formule (Formula bar) kliknite mišem iza prvog argumenta Vlookup funkcije (tj. postavite kursor unutar prvog argumenta).
  3. Sada vam se pojavio okvir koji prikazuje sve argumente Vlookup funkcije. Unutar ovog okvira kliknite na treći argument Vlookup funkcije (col_index_num).
  4. Uočite da se sada označila Match funkcija koju sam ugnijezdio.
  5. Pritisnite tipku F9

Result of Embed or Nested Excel Function

Nakon pritiska tipke F9 uočite da je Excel automatski izračunao rezultat Match funkcije i prikazao ga u formula baru. Excel je prikazao broj "3" (slika ispod) što je broj stupca iz kojega želimo prikazati rezultat Vlookup formula.

Rezultat ugniježđene Excel funkcije

Na ovaj način koristeći tipku F9 na tipkovnici brzo možete saznati rezultat bilo koje funkcije koja je ugniježđena unutar neke druge Excel funkcije ili kompleksne Excel formule.




     

sponzor



COPYRIGHT © - 2005 - 2019 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela