logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCE 2013 tutoriali - Spremi radnu knjigu kao vrijednosti, Spremi radni list kao tekst, Spremi radnu knjigu kao vrijednosti bez formula, Spremi radni list samo kao tekst

Spremi radnu knjigu kao vrijednosti -
Spremi radni list kao tekst -
Spremi sve radne listove bez formula




sponzor



Kako spremiti radni list ili radnu knjigu kao vrijednosti ili kao tekst bez formula u Excelu

Ako čitate ovaj Excel tutorijal, vjerujem da ste korisnik Excela koji ima potrebu spremiti radnu knjigu ili spremiti radni list kao tekst, ali tako da spremljena radna knjiga ne sadrži formule. Suočen nedavno sa istom potrebom, odlučio sam na jedno mjesto prikupiti više raznih varijanti VBA makronaredbi koje rade istu radnju ali na različite načine. Ovaj Excel tutorijal sadrži kolekciju VBA makronaredbi raznih autora i sve zasluge pripadaju autorima tj. kreatorima VBA makronaredbi (izvor: answers.microsoft.com, rondebruin.nl, mrexcel.com, excelforum.com, extendoffice.com, internet mreža itd).

Kao što znate kod VBA makronaredbe ili procedure, ima početak i kraj koji između te dvije linije koda sadrži druge dijelove VBA koda za određenu radnju. Sve VBA makronaredbe prikazane na ovoj web stranici, odnose se na aktivnu radnu knjigu koja sadrži više radnih listova ili na aktivni radni list. Ako tražite VBA makronaredbu, koja sprema sve radne listove u višestrukim radnim knjigama koji se nalaze u više mapa i podmapama tada pogledajte prethodni tutorijal.

- Spremanje svih radnih listova kao tekst u višestrukim radnim knjigama u svim mapama i podmapama

Svaka VBA makronaredba ima događaj u kojem je implementiran VBA kod za određenu radnju. U tekstu ispod prikazana je osnova jedne VBA procedure.
PAŽNJA! Sve VBA makronaredbe prikazana na ovoj web stranici koristite na vlastitu odgovornost. Savjetujem da radite na kopiji vaše radne knjige.

Snimanje VBA makronaredbe za određenu radnju u Excelu

Kada je u pitanju rad sa VBA makronaredbama u Excelu, krenimo od početka. Za svaku radnju koju često ponavljamo, možemo snimiti VBA makronaredbu. U ovom slučaju pokazat ću vam kako možete snimiti VBA makronaredbu koja će uraditi slijedeće:

  1. Na aktivnom radnom listu koji sadrži puno formula
  2. Selektirati sve ćelije
  3. Naredbom Copy - izvršiti kopiranje svih selektiranih ćelija
  4. Naredbom Paste zalijepiti kopirane ćelije kao vrijednosti (bez formula)

Pojedinačne korake za snimanje VBA makronaredbe opisao sam u ovom Excel tutorijalu. Također možete pogledati VIDEO na YouTube.

Dakle, ovo je primjer snimljene VBA makronaredbe koristeći naredbu "Record Macro" u Excelu

Sub Macro1()
Cells.Select 'the user used the Ctrl+A
Selection.Copy 'the user used the Ctrl+C
'the user used the Paste button -> Paste Values
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Range("A1").Select 'the user clicked on A1 cell
End Sub

Spremi formulu kao vrijednost u Excelu

Kako brzo i jednostavno zamijeniti formulu rezultatom

Ako radite sa rasponima ćelija i imate puno formula na radnom listu a u određenom trenutku želite formulu zamijeniti rezultatom učinite slijedeće:

Prvi način

  1. Desni klik mišem na ćeliju 'Copy'
  2. Desni klik mišem na ćeliju i izaberite 'Paste Special' (Posebno ljepljenje)
  3. Označite radio button 'Values' (Vrijednosti)
  4. Kliknite OK button

Drugi način

  1. Selektirajte ćeliju u kojoj se nalazi formula i sadrži rezultat dobiven formulom
  2. Pritisnite tipku 'F2'
  3. Pritisnite tipku 'F9'
  4. Pritisnite Enter tipku

Treći način

  1. Selektirajte ćeliju/raspon ćelija u kojoj se nalaze formule i sadrže rezultat dobiven formulama
  2. Pritisnite kombinaciju tipki 'CTRL+C'
  3. Pritisnite kombinaciju tipki 'SHIFT+F10+V' (tipku Shift zadržite)
  4. Pritisnite Enter tipku da poništite selekciju

Četvrti način

  1. Selektirajte ćeliju/raspon ćelija u kojoj se nalaze formule i sadrže rezultat dobiven formulama
  2. Pritisnite kombinaciju tipki 'CTRL+C'
  3. Pritisnite kombinaciju tipki 'ALT+E+S+V' (tipku Alt zadržite)
  4. Klinite OK button

Peti način

  1. Pritisnite kombinaciju tipki 'CTRL+A'
  2. Pritisnite kombinaciju tipki 'CTRL+C'
  3. Kliknite naredbu Paste -> Paste Special -> Values

Sada umjesto formule ćelija ili raspon sadrži vrijednost ili tekst

Primjer osnovne VBA procedure

U principu VBA makronaredbe koji su prikazani na ovoj web stranici kopirajte u standardni Module u vašem Excel VBE

Option Explicit
Sub SaveAsValues() 'title of subprocedure
Declared variables
Application.ScreenUpdating = False 'option 'Optimize Macro Speed
Application.EnableEvents = False 'option 'Optimize Macro Speed
'''''''''''''''''''''''''''''''''''
'--YOUR CODE HERE--
'''''''''''''''''''''''''''''''''''
Application.CutCopyMode = False 'disable selection
Application.EnableEvents = True 'option 'Reset Macro Optimization Settings
Application.ScreenUpdating = True 'option 'Reset Macro Optimization Settings
MsgBox "Process Completed!" 'option Message Box when process are completed
End Sub 'end of subrpcedure

Konvertiraj sve formule u vrijednosti na svim radnim listovima

Kratka i jednostavna VBA makronaredba za konvertiranje formule u vrijednosti na svim radnim listovima u otvorenoj radnoj knjizi je ova ispod. Ako jednu od ove dvije želite ugraditi u neku drugu VBA proceduru, tada uočite da nema naredbene linije koda koja bi spremila izmjene u radnoj knjizi. Dakle trebali bi dodati kod za spremanje (snimanje).

Sub ConvertFormulasToValues()
Dim ws As Worksheet
For Each ws In Worksheets
ws.UsedRange = ws.UsedRange.Value
Next ws
End Sub

ili ova ispod VBA makronaredba

Sub SaveAllFormulasAsValues()
Dim sh As Worksheet
For Each sh In ActiveWorkbook.Worksheets
With sh.UsedRange
.Value = .Value
End With
Next sh
End Sub

ili ova VBA makronaredba ispod

Sub SaveAllFormulasAsTextOrValues()
Dim w As Long
For w = 1 To Sheets.Count
Sheets(w).UsedRange = Sheets(w).UsedRange.Value
Next w
End Sub

Spremi aktivnu radnu knjigu kao vrijednosti bez formula - napravi kopiju u XLSX format

Primjer 1

Ova VBA makronaredba ispod, sprema aktivnu radnu knjigu formata *.XLSM kao kopiju u *.XLSX formatu. Uočite linije koda koje su namijenjene ako želite u naziv spremljene radne knjige dodati datum tj. godinu i mjesec. Izvorna aktivna knjiga ostaje nepromijenjena. U spremljenoj kopiji neće postojati VBA module kao ni VBA makronaredbe ako ih ima u ostalim modulima.

Option Explicit
Sub SaveAsValuesAllSheetsAndSaveWbkAsXLSX()
'author Jeeped
'answers.microsoft.com
'modified by www.ic-ims.com
Dim w As Long
Application.ScreenUpdating = False 'option 'Optimize Macro Speed
Application.EnableEvents = False 'option 'Optimize Macro Speed
For w = 1 To Sheets.Count
Sheets(w).UsedRange = Sheets(w).UsedRange.Value
Next w
Application.DisplayAlerts = False
''save with date year and month in filename
' ThisWorkbook.SaveAs _
' ThisWorkbook.Path & Chr(92) & _
' Left(ThisWorkbook.Name, InStr(1, ThisWorkbook.Name, Chr(46)) - 1) & Format(Date, "_yyyy-mm"), _
' xlOpenXMLWorkbook
'save without date in filename

ThisWorkbook.SaveAs _
ThisWorkbook.Path & Chr(92) & _
Left(ThisWorkbook.Name, InStr(1, ThisWorkbook.Name, Chr(46)) - 1), _
xlOpenXMLWorkbook
Application.EnableEvents = True 'option 'Reset Macro Optimization Settings
Application.ScreenUpdating = True 'option 'Reset Macro Optimization Settings
MsgBox "Process Completed!" 'option Message Box when process are completed
End Sub

Primjer 2

Ova VBA makronaredba ispod prolazi kroz sve radne listove aktivne radne knjige i sprema radnu knjigu bez formula (kao vrijednosti). Nakon pokretanja makronaredbe pojavit će vam se dijalog prozor 'SaveAs' i potrebno ja da postavite naziv za novu radnu knjigu i izaberete mapu u koju ćete spremiti radnu knjigu.

Sub SaveTheWorkbookAsValuesOnly()
'by Dave Hawley
'ozgrid.com
'modified by www.ic-ims.com
Dim wSheet As Worksheet
Application.ScreenUpdating = False 'option 'Optimize Macro Speed
Application.EnableEvents = False 'option 'Optimize Macro Speed
On Error Resume Next
For Each wSheet In Worksheets
With wSheet.UsedRange
.Copy
.PasteSpecial xlPasteValues
End With
Next wSheet
Application.CutCopyMode = False
On Error GoTo 0
Application.EnableEvents = True 'option 'Reset Macro Optimization Settings
Application.ScreenUpdating = True 'option 'Reset Macro Optimization Settings
Application.Dialogs(xlDialogSaveAs).Show
End Sub

Spremi sve radne listove kao vrijednosti bez formula

Primjer 3

U ovom trećem primjeru prikazuje dva načina na koji možemo proći kroz sve radne listove i konvertirati sve formule u njihove rezultate ili vrijednosti. Uočite razliku u dijelovima koda koji se odnosi na sve radne listove. Za ostale VBA makronaredbe posjetite njegovu web stranicu.

Prvi način

Sub SaveAllWorksheetAsValues()
'by rondebruin.nl
'modified www.ic-ims.com

Dim sh As Worksheet
Application.ScreenUpdating = False
'option 'Optimize Macro Speed
Application.EnableEvents = False
'option 'Optimize Macro Speed
For Each sh In ActiveWorkbook.Worksheets
sh.Select
With sh.UsedRange
.Cells.Copy
.Cells.PasteSpecial xlPasteValues
.Cells(1).Select
End With
Application.CutCopyMode = False
Next sh
Application.EnableEvents = True 'option 'Reset Macro Optimization Settings
Application.ScreenUpdating = True 'option
'Reset Macro Optimization Settings
End Sub

Primjer 4

Ova VBA makronaredba sprema sve radne listove (unutar aktivne radne knjige) kao vrijednosti

Option Explicit
Sub SaveAsValuesOnly()
Dim wsh As Worksheet
For Each wsh In ThisWorkbook.Worksheets
wsh.Cells.Copy
wsh.Cells.PasteSpecial xlPasteValues
Next
Application.CutCopyMode = False
End Sub

Spremi sve formule kao vrijednosti ili tekst za definirani raspon ćelija na aktivnom radnom listu

U ovom dijelu primjera za konvertiranje formula u vrijednosti ili tekst VBA makronaredbe daju isti rezultat na drugačije načine. Sve zasluge pripadaju autorima istih (source: mrexcel.com)

Primjer 5

Sub ChangeOrConvertToValues()
'used range B:D on active sheet
With Range("B2", Cells(Rows.Count, "D").End(xlUp).Offset(-1)) 'not include last row -> -1
.Value = .Value
End With
End Sub

Primjer 6

Sub SaveAsValues1()
'non-adjacent ranges on active sheet
Dim Cl As Range
For Each Cl In Range("A2:B33,D2:E33")
Cl.Value = Cl.Value
Next Cl
End Sub

Primjer 7

Sub SaveAsValues2()
'non-adjacent ranges on active sheet
Dim c As Range
Dim rng As Range
Set rng = Range("A2:B33,D2:E33")
For Each c In rng.Cells
c = c.Value
Next
End Sub

Primjer 8

Sub SaveAsValues3()
'non-adjacent ranges on active sheet
Dim oneArea As Range
For Each oneArea In Range("A2:B33,D2:E33").Areas
oneArea.Value = oneArea.Value
Next oneArea
End Sub

Spremi sve formule kao vrijednosti ako počinju sa specifičnim izrazom

U ovom primjeru ispod uočite VBA makronaredbu koja će proći kroz sve radne listove u aktivnoj radnoj knjizi i pronaći određene formule koje počinju sa specifičnim izrazom (u ovom slučaju to je početak formule =helper! koja sadrži 8 znakova). Kada VBA pronađe takvu formulu istu će zamijeniti rezultatom dotične formule. Ovu interesantnu VBA makronaredbu možemo koristiti ako želimo samo određene formule konvertirati u vrijednosti.

Primjer 9

'Option Explicit
Sub ReplaceCertainFormulaOnMultipleTabsAsValues()
'author sheetspread
'source mrexcel.com
'published by www.ic-ims.com
Dim x As Integer
For x = 1 To Sheets.Count
For Each Cell In Sheets(x).UsedRange
If Left(Cell.Formula, 8) = "=helper!" Then 'the beginning of the formula
Cell.Value = Cell.Value
End If
Next Cell
Next x
End Sub

Transformiraj formule u vrijednosti na aktivnom radnom listu

Ova dva primjera ispod prikazuju VBA makronaredbe koje transformiraju ili konvertiraju formule u vrijednosti za određeni raspon ćelija na aktivnom radnom listu. U primjeru 10 definiran je raspon ćelija a u primjeru 11 korisnik prije pokretanja VBA makronaredbe treba selektirati određeni raspon ćelija u kojem se nalaze formule (source: extendoffice.com)

Primjer 10

Sub TransformFormulasToValues()
'Converts formulas to text or values in the defined range
With Range("A1:A100")
.Value = .Value
End With
End Sub

Primjer 11

Sub TransformFormulasToValues2()
'Converts formulas to text or values in the selected range
With Selection
.Value = .Value
End With
End Sub

U otvorenoj radnoj knjizi spremi kao vrijednosti višestruke radne listove i zaštiti ih lozinkom

Ova VBA makronaredba ispod, nakon spremanja svih formula kao vrijednosti automatski zaključava/zaštićuje radni list definiranom lozinkom.

Sub ConvertFormulasToValuesAndLockSheets()
'published by www.ic-ims.com
Dim ws As Worksheet
Dim pwd As String
'add option if you want 'Optimize Macro Speed
pwd = "123"
For Each ws In Worksheets
'ws.Unprotect Password:=pwd 'option if password exist, unlock sheet
ws.UsedRange = ws.UsedRange.Value
ws.Protect Password:=pwd, UserInterfaceOnly:=True 'lock sheet
ws.EnableOutlining = True
Next ws 'next sheet
'add option if you want'Reset Macro Optimization Settings
MsgBox "Process Completed!" 'option Message Box when process are completed
End Sub

Sve VBA makronaredbe, prikazane na ovoj web stranici vezane su uz spremanje radnih listova ili radne knjige bez formula, tj. konvertiranje formula u njihove rezultate. Na internetu možete pronaći još različitih načina i drugačijih VBA makronaredbi. Nadam se da će vam ova kolekcija VBA makronaredbi pomoći u korištenju Excela ako trebate spremiti vaš rad bez formula.




   

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela