logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali - Excel funkcije RAND() i RANDBETWEEN(),

Primjeri RAND() i RANDBETWEEN() funkcija u Excelu




sponzor



Excel funkcije RAND i RANDBETWEEN

U ovom Excel tutorijalu pokazat ću kolekciju Excel formula koje koriste RAND i RANDBETWEEN funkcije. Ako imate potrebu prikazati nasumično odabrane brojeve u nekom rasponu ili slučajne vrijednosti tada proučite ovaj tutorijal i kolekciju Excel formula prikazanih ispod.

Excel RAND funkcija

Sintaksa ove funkcije izgleda ovako
=RAND()

Nakon unosa ove formule iznad Excel će vratiti slučajni broj ili slučajnu vrijednost sa šest decimala. U koliko RAND() funkciju želite koristiti za raspon brojeva tada možete upotrijebiti ovu formulu (X je najmanji broj a Y je najveći broj). Umjesto ove druge formule možete jednostavno upotrijebiti RANDBETWEEN funkciju.
=RAND()*(y-x)+x

Excel RANDBETWEEN funkcija

Sintaksa ove funkcije izgleda ovako
=RANDBETWEEN(bottom;top)

Ako želite prikazati slučajne vrijednosti između nekog raspona brojeva tada koristite ovu Excel funkciju. Kao što možete zaključiti 'bottom' argument je najmanji broj a 'top' argument je najveći broj.

NAPOMENA: Pritiskom na 'F9' tipku automatski osvježavate nove slučajne vrijednosti (brojeve).

RAND funkcija i generiranje slučajno odabranih brojeva od 1 do 20

Na slici ispod možete uočiti rezultate bazirane na Excel RAND() funkciji. Ima tu još drugih ugniježđenih funkcija ali baza je RAND funkcija. Pomoću RAND funkcije možemo generirati slučajne brojeve (slučajne vrijednosti) kao u 'A' stupcu na Slika 1.

Slika 1.

Primjeri RAND funkcije u Excelu

Formula na Slika 1 su slijedeće:

Formula u 'A2' kopirana dole je slijedeća: (Ova formula generira slučajne vrijednosti u 'A' stupcu.
=RAND()

Formula u 'B2' kopirana dole je slijedeća: (Ova formula rangira vrijednosti iz 'A' stupca. Dakle rezultat ove formule za određenu vrijednost je redoslijed vrijednosti u brojevnom nizu. Naravno ovdje nema duplikata jer su svi rezultati jedinstvene vrijednosti)
=RANK(A2;A$2:A$21)

Formule u 'D', 'E' i 'F' stupcima su povezane u jednu cjelinu. U 'D2' ćeliji unesen je broj 20. Taj broj označava da želimo dvadeset brojeva (vrijednosti) iz 'A' stupca. Ovi rezultati su slični kao i u 'B' stupcu, samo su postavljeni u dva stupca po deset brojeva.

Formula u 'E2' ćeliji je slijedeća: (Ovu formulu kopirajte u 'F' stupac pa sve prema dole. (U ovoj formuli ima više ugniježđenih Excel funkcija poput: ROW, RANK, OFFSET, LARGE, MATCH, COLUMN, INDEX)
=IF(ROW()-ROW(E$2)+1>$D$2/2;"";RANK(OFFSET($A$2;ROW()-ROW(E$2)+(COLUMN()-COLUMN($E2))*($D$2/2););$A$2:INDEX($A$2:$A$21;$D$2)))

Formula u 'H' stupcu je slijedeća: (Ova formula zamjenjuje Excel RANDBETWEEN funkciju, X i Y su krajnje vrijednosti između kojih tražimo slučajne ili nasumične generirane vrijednosti. Ako pogledate formulu ispod, tada možete uočiti da sam postavio krajnje vrijednosti, broj 1 kao najmanji i broj 20 kao najveći.)
=RAND()*(20-1)+1

Formula u 'I' stupcu je slijedeća: (Ova formula je standardna za rangiranje vrijednosti u određenom rasponu ćelija)
=RANK(H2;H$2:H$21)

RANDBETWEEN funkcija i generiranje slučajno odabranih vrijednosti u decimalama

Excel RANDBETWEEN funkcija generira niz vrijednosti između dva zadana uvjeta. Ti uvjeti su najniža i najviša vrijednost. Na Slika 2 uočite tri stupca u kojima su prikazani primjeri korištenja RANDBETWEEN funkcije.

Slika 2.

Primjeri RANDBETWEEN funkcije u Excelu

Formula u 'A2' ćeliji na slici iznad je slijedeća: (Uočite da sam postavio broj 1 kao najmanju vrijednost i broj 10 kao najvišu vrijednost. Rezultat ove formule ispod je broj bez decimalnih vrijednosti)
=RANDBETWEEN(1;10)

Formula u 'B2' ćeliji na slici iznad je slijedeća: (Rezultat ove formule su vrijednosti zaokružene na dvije decimale. Uočite da je najniža vrijednost broj 20 a najviša vrijednost je broj 30).
=RANDBETWEEN(20;30)/100

Formula u 'C2' ćeliji na slici iznad je slijedeća: (Rezultat ove formule su negativne vrijednosti zaokružene na tri decimale. Uočite da je najniža vrijednost broj -100 a najviša vrijednost je broj -90).
=RANDBETWEEN(-100;-90)/1000

Generiranje grupe slučajnih slova od 'A' do 'Z'

Na Slika 3 ispod, uočite kako možemo generirati slučajne grupe slovnih oznaka (nasumično generirati grupe karaktera slova) ako je prvo malo slovo 'a' a zadnje malo slovo 'z'.

Slika 3.

Generiranje nasumičnih grupa po šest slova

Formula u 'E2' ćeliji je slijedeća: (Karakter, malo slovo 'a' može se predstaviti koristeći tekstualnu CODE funkciju tj. Excel formulom ispod. Uočite da je formula vratila rezultat numerički kod 97 za malo slovo 'a').
=CODE(D2)

Formula u 'B2' ćeliji je slijedeća: (Baza ove formule su CHAR i RANDBETWEEN funkcije. CHAR funkcija kao rezultat vraća karakter slova za određeni broj kao uvjet. Tako će formula =CHAR(97) kao rezultat vratiti malo slovo 'a'. Naravno u CHAR formulu ugniježđena je RANDBETWEEN funkcija).
=CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))&CHAR(RANDBETWEEN(97;122))&CHAR(RANDBETWEEN(97;122))

Pogledajte raspon ćelija 'G2:L11' na Slika 3 iznad. Uočite da se u svakoj ćeliji ovog raspona nalazi šest slovnih karaktera. Ovaj niz nasumičnih grupa slova u rasponu dobiven je ovom formulom ispod: (Formulu kopirajte u desno pa zatim sve kopirajte prema dole).
=CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))&
CHAR(RANDBETWEEN(97;122))

Generiranje liste slučajnih brojeva iz raspona ćelija

Ako imate popis vrijednosti koje se nalaze u rasponu i želite odabrati slučajne vrijednosti iz tog popisa tada opet možete koristiti RANDBETWEEN funkciju ugniježđenu unutar INDEX formule. Uočite da je ista formula korištena za oba argumenta (row_num, column_num) funkcije INDEX. Jedina razlika je vrijednost drugog argumenta unutar RANDBETWEEN formule. S obzirom da argument 'row_num' INDEX funkcije zahtijeva broj reda a mi imamo deset redova u rasponu ćelija, zato sam postavio najvišu vrijednost 10. Isto se odnosi i na broj stupaca. Nadam se da ćete shvatiti, da ne pišem puno sada. U stvari, proučite detaljnije INDEX funkciju, njenu sintaksu i argumente. Vidi Slika 4 ispod.
=INDEX($A$1:$E$10;RANDBETWEEN(1;10);RANDBETWEEN(1;5))

Slika 4.

Generiranje liste slučajnih brojeva iz raspona ćelijaa

Kako prikazati ili odabrati slučajno ime iz popisa imena

Ako želite odabrati slučajno ime ili tekst iz nekog raspona ćelija, tada iskoristite formule ispod Slika 5. Uočite na slici ispod da u rasponu 'A2:A8' nalaze se imena osoba. Naš cilj je kao rezultat vratiti neko slučajno odabrano ime (nešto slično kao generiranje loto brojeva :)

Slika 5.

Kako prikazati ili odabrati slučajno ime iz popisa imena

Na slici iznad uočite dvije formule, koje vraćaju slučajno odabrano ime iz popisa imena.

Formula u 'C2' ćeliji je slijedeća: (Uočite da je RANDBETWEEN funkcija ugniježđena unutar CHOOSE funkcije).
=CHOOSE(RANDBETWEEN(1;7);A2;A3;A4;A5;A6;A7;A8)

Formula u 'C4' ćeliji je slijedeća: (U ovoj formuli korištena su samo prva dva argumenta INDEX funkcije. Dakle, korišteni su 'array' i 'row_num' argumenti. Nema potrebe koristiti ostale argumente jer imamo samo jedan stupac kao raspon).
=INDEX($A$2:$A$8;RANDBETWEEN(1;7))


Generiraj slučajne brojeve za Loto - Generator Loto brojeva

Ovaj primjer na Slika 6 vezan je za LOTO igru na sreću. U 'A' stupcu generirani su svi brojevi od najmanjeg broja 1 do najvećeg 39. Formula je ispod. Ako se pitate kako sada govorim da sam odredio najmanji i najveći broj a koristio sam RAND funkciju. Pa jednostavno pogledajte broje redova u 'A' stupcu.
=RAND()

Slika 6.

Generiranje slučajnih Loto brojeva

U drugom retku Slika 6. startavši od 'C2' ćelije do 'G2' ćelije korištena je formula ispod. (ova formula bazirana je na 'A' stupcu i vraća slučajni broj iz raspona. Pretpostavljam da znate da MATCH funkcija, kao rezultat vraća broj reda tj. u ovom slučaju vraća vrijednost iz određenog reda).
=MATCH(LARGE($A$1:$A$39;COLUMN(A1));$A$1:$A$39;0)

Extra Loto broj u 'H2' ćeliji dobiven je standardnom formulom ispod.
=RANDBETWEEN(1;39)

Ako ne želite koristiti prethodno navedenu varijantu, možete upotrijebiti dva uvjeta za minimalnu i maksimalnu vrijednost (najmanji broj i najveći broj) kao u 'G8' i 'G9' ćelijama.

CSE Formula u 'C9' ćeliji je slijedeća: (Ova ARRAY formula vraća jedinstvene brojeve između dva uvjeta. Formulu kopirajte dole do željenog reda).
=IFERROR(LARGE(ROW(INDIRECT($G$8&":"&$G$9))*NOT(COUNTIF($C$8:C8;
ROW(INDIRECT($G$8&":"&$G$9))));RANDBETWEEN(1;$G$9-$G$8-ROW(A1)+2));"")

Automatsko generiranje popisa imena

Ako želite automatski generirati slučajni redoslijed teksta (u ovom slučaju nasumični redoslijed imena osoba, tada pogledajte Slika7 ispod. U ovom slučaju korišteni su pomoćni stupci ili pomoćne kolone 'C' i 'E' koje naravno možete vizualno sakriti. Na slici ispod uočite popis imena u 'A' stupcu. U 'F' stupcu koristeći formulu, generiran je popis imena u slučajnom redoslijedu.

Slika 7.

Lista imena sa slučajnim rasporedom

Formula u 'C' stupcu je slijedeća: (Opet smo koristili standardnu RAND formulu koja je vratila devet nasumičnih brojeva).
=RAND()

U 'E' stupcu postavljen je pomoćni stupac u kojem se nalazi formula ispod: (ova formula rangira vrijednosti iz 'C' stupca.
=RANK(C2;$C$2:$C$10)

I na kraju, prikaz slučajnog redoslijeda imena osoba u 'F' stupcu, dobiven je formulom ispod.
=INDEX($A$2:$A$10;MATCH(ROW(A1);$E$2:$E$10;0))

Ja se nadam da sam ovim tutorijalom uspio donekle približiti vam kako rade dvije Excel funkcije RAND i RANDBETWEEN.

Pritisnite 'F9' tipku da bi osvježili kalkulaciju formule. Zapamtite, nakon pritiska na 'F9' tipku, sve vrijednosti (svi brojevi) koji su dobiveni Excel funkcijama RAND i RANDBETWEEN, automaski se osvježavaju (automatski mijenjaju na svakom radnom listu koji sadrži dotičnu Excel funkciju).

I na kraju u prilogu ovog tutorijala imate mogućnost Download datoteke na kojoj sam radio ovaj tutorijal.




     

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela