logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCE 2013 tutoriali -Prikaz imena trenutnog foldera u ćeliji, Kako prikazati putanju do foldera (direktorija) u ćeliji, u kojem se nalazi otvorena Excel radna knjiga, Kako prikazati ime trenutnog sub foldera (direktorija) u ćeliji u kojoj se nalazi otvorena Excel radna knjiga, Kako radi formula za prikaz imena foldera otvorene datoteke, Get the current subfolder name in a cell, Display subfolder name only where is placed opened Workbook, Kako prikazati ime samo subfoldera u kojem se nalazi otvorena Excel radna knjiga ali ne i cijelu putanju

Prikaz imena trenutnog foldera u ćeliji
(Display the current subfolder name in a Excel cell)




sponzor



Kako prikazati putanju do foldera (direktorija) u ćeliji, u kojem se nalazi otvorena Excel radna knjiga

Vjerujem da vam je poznata formula pomoću koje možete dobiti (prikazati) putanju ili stazu do foldera u kojem se nalazi otvorena radna knjiga (datoteka). Ako vam formula nije poznata evo je. Ova formula ispod prikazuje cijelu putanju do foldera u kojem se nalazi otvorena datoteka.

=LEFT(CELL("filename";A2);FIND("[";CELL("filename";A2);1)-1)

Rezultat je kao na slici ispod

Formula za putanju do Excel Workbook

Kako vratiti ime trenutnog foldera (direktorija) u ćeliji u kojoj se nalazi otvorena Excel radna knjiga

Ako želite prikazati samo ime ili naziv foldera u kojem se nalazi otvorena Excel datoteka (Excel Workbook) tada iskoristite ovu formulu ispod (formula se piše u jednoj naredbenoj liniji). Vidi rezultat formule u A7 ćeliji na slici iznad.

=IFERROR(TRIM(SUBSTITUTE(MID(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1);FIND(CHAR(1);SUBSTITUTE(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1);"\";CHAR(1);(LEN(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1))-LEN(SUBSTITUTE(LOWER(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1));"\";"")))/1-1))+1;100);"\";""));"")

Ako vas zanima kako radi ova formula (iz koji sve dijelova se sastoji formula) tada bi trebali poznavati argumente za određene funkcije. Naravno, vi možete koristiti Evaluate formula ili F9 tipku na tipkovnici.

Kako radi formula za prikaz imena foldera otvorene datoteke

Ova dugačka formula iznad za prikazivanje foldera u kojem je smještena otvorena radna knjiga, sastoji se od više ugniježđenih funkcija (formula). Da bi ste mogli shvatiti kako formula funkcionira, potrebno je da koristite "vrednovanje formule" ili tipku F9 na tipkovnici koja vrši izračun selektiranog argumenta funkcije.

Dakle potrebno je poznavati argumente određene funkcije koju želimo koristiti. Ja ću u nastavku ovog tutorijala pokušati pokazati kako mi možemo kreirati jednu dugačku Excel formulu od više ugniježđenih Excel funkcija. Pogledajte sliku ispod i pratite je tokom pregledavanja ovog tutorijala. Uočite korake koji na kraju prikazuju željeni rezultat.

Prikaz naziva foldera u kojem je smještena radna knjiga

U ćeliji 'A2' nalazi se formula koja prikazuje cijelu putanju do poddirektorija u kojem se nalazi otvorena Excel datoteka. Pogledaj prvu formulu na početku ovog tutorijala.

U ćeliji 'A7' nalazi se formula koja broji koliko je karaktera "\" u ćeliji A2 i naravno minus jedan karakter jer želimo prebrojiti sve karaktere do pred zadnjeg karaktera. Ako mi znamo formulu za brojanje ukupnog broja specifičnih karaktera onda je jednostavno izračunati ukupan zbroj minus jedan karakter. Rezultat ove formule je broj '8'. To znači da u rezultatu formule nalazi se 9 znakova "\". Naravno minus jedan znak i rezultat je 8.

Formula u 'A8' ćeliji (9-1=8)
=((LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);"\";"")))/1)-1

U ćeliji 'A11' nalazi se formula kreirana koristeći Excel funkciju FIND, koja kao rezultat vraća poziciju pred zadnjeg karaktera. Ako znamo da funkcija =LEN(A2) vraća ukupan broj karaktera u ćeliji tada je jednostavno vratiti položaj predzadnjeg specifičnog karaktera. Vi možete uočiti u formuli ispod da funkcija SUBSTITUTE ima zadnji argument "instance_num" koji je u ovom slučaju podatak iz ćelije 'A8'. Ako vi selektirate argument "within_text" Excel funkcije FIND i koristite tipku F9 tada ćete vi uočiti da ova funkcija vraća putanju do subfoldera u kojem se nalazi otvorena datoteka (Workbook). Rezultat formule ispod je vrijednost 74. To znači da se pred zadnji karakter "\" nalazi na 74 mjestu ukupnog broja karaktera.

Formula u A11 ćeliji
=FIND(CHAR(1);SUBSTITUTE(A2;"\";CHAR(1);A8))

U ćeliji 'A14' nalazi se formula kreirana koristeći Excel funkciju MID. Ova formula vraća ime subfoldera u kojem se nalazi otvorena Excel radna knjiga. Vi možete uočiti da rezultat također prikazuje zadnji karakter "\". Njega će mo ukloniti kasnije. Ova formula koristi podatke ćelija 'A2' i 'A11'. Vrijednost ili broj "100" unutar funkcije, je zadnji argument Excel funkcije MID. Ovaj broj vi možete mijenjati po želji a on zavisi o maksimalnom broju očekivanih znakova ili karaktera, naziva subfoldera u kojem se nalazi otvorena Excel radna knjiga.

Formula u 'A14' ćeliji
=MID(A2;A11+1;100)

U ćeliji 'A17' nalazi se formula u koju smo ugnijezdili prethodne formule. Tako, u formuli ispod imamo ugniježđenu formulu iz ćelije 'A11' u ćeliju 'A14'. Asocijacija na ostale ugniježđene formule bi izgledala kao ispod.
=MID(text;start_num;num_chars)
=MID(A2; FIND(CHAR(1);SUBSTITUTE(A2;"\";CHAR(1);A8_cell))+1;100)
=MID(A2;A11+1;100)

Formula u 'A17' ćeliji (Ako +1 zamjenimo sa nulom tada ćemo dobiti jedan specifični karakter ispred u imenu subfoldera)
=MID(A2;FIND(CHAR(1);SUBSTITUTE(A2;"\";CHAR(1);(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);"\";"")))/1-1))+1;100)

U ćeliji 'A20' nalazi se formula koristeći Excel funkciju TRIM, koja koristi rezultat iz ćelije 'A17' i uklanja zadnji karakter "\".

Formula u ćeliji 'A20' je ispod
=TRIM(SUBSTITUTE(A17;"\";""))

Ako umjesto adrese ćelije 'A17' u formuli iznad, ugnijezdimo formulu iz ćelije 'A17' tada naša formula u ćeliji 'A23' izgleda kao ispod.

Formula u ćeliji 'A23'
=TRIM(SUBSTITUTE(MID(A2;FIND(CHAR(1);SUBSTITUTE(A2;"\";CHAR(1);(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);"\";"")))/1-1))+1;100);"\";""))

I na kraju naša formula koja vraća željeni rezutat, poslije svih ugniježđenih formula u ćeliji 'A26' izgleda kao ispod. Vi uočite da sam ja u prethodnu formulu iznad, umjesto 'A2' adrese ćelije ugnijezdio formulu sa početka ovog tutorijala koja vraća cijelu putanju do pod direktorija.

Kako prikazati ime samo subfoldera u kojem se nalazi otvorena Excel radna knjiga ali ne i cijelu putanju

Konačna formula u ćeliji 'A26' je slijedeća (formula se nalazi u jednoj naredbenoj liniji)
=IFERROR(TRIM(SUBSTITUTE(MID(LEFT(CELL("filename";A2);FIND("[";CELL("filename";A2);1)-1);FIND(CHAR(1);SUBSTITUTE(LEFT(CELL("filename";A2);FIND("[";CELL("filename";A2);1)-1);"\";CHAR(1);(LEN(LEFT(CELL("filename";A2);FIND("[";CELL("filename";A2);1)-1))-LEN(SUBSTITUTE(LOWER(LEFT(CELL("filename";A2);FIND("[";CELL("filename";A2);1)-1));"\";"")))/1-1))+1;100);"\";""));"")

IFERROR funkcija nam služi da uklonimo eventualne greške (ali nije neophodna).
=IFERROR(našaFormula;"")

Ja se nadam da ste razumjeli što sam ja htio pokazati u ovom tutorijalu. Dakle kako prikazati ime subfoldera (pod direktorija) u kojem se nalazi otvorena Excel radna knjiga. Ako ovu formulu kopirate u više Excel radnih knjiga bez obzira na kojem mjestu su smještene, ova formula će uvijek ispravno vratiti točan naziv subfoldera u kojem je smještena trenutno otvorena Excel radna knjiga.

BTW: Isto rješenje možete dobiti formulama koje su kreirane pomoću drugih ugniježđenih formula. (Pažnja! Formula treba biti u jednoj naredbenoj liniji)

Ugniježđena formula 1 (IvanC)
=LEFT(MID(CELL("filename";$A1);FIND("[";SUBSTITUTE(CELL("filename";$A1);"\";"[";(LEN(CELL("filename";$A1))-LEN(SUBSTITUTE(LOWER(CELL("filename";$A1));"\";"")))/1-1))+1;100);FIND("\";MID(CELL("filename";$A1);FIND("[";SUBSTITUTE(CELL("filename";$A1);"\";"[";(LEN(CELL
("filename";$A1))-LEN(SUBSTITUTE(LOWER(CELL("filename";$A1));"\";"")))/1-1))+1;100))-1)

ili

=TRIM(LEFT(LEFT(MID(CELL("filename";$A1);FIND("[";SUBSTITUTE(CELL("filename";$A1);"\";"[";(LEN(CELL("filename";$A1))-LEN(SUBSTITUTE(LOWER(CELL("filename";$A1));"\";"")))/1-1))+1;100);100);FIND("\";LEFT(MID(CELL("filename";$A1);FIND("[";SUBSTITUTE(CELL("filename";$A1);"\";"[";
(LEN(CELL("filename";$A1))-LEN(SUBSTITUTE(LOWER(CELL("filename";$A1));"\";"")))/1-1))+1;100);100);1)-1))

Ugniježđena formula 2 (autor osnovne formule AliGW)
=TRIM(LEFT(SUBSTITUTE(RIGHT(SUBSTITUTE(SUBSTITUTE( LEFT(CELL("filename";A20);FIND("]";CELL("filename";A20))-1);"[";"");"\";REPT(" ";300));600);REPT(" ";300);"\");FIND("\";SUBSTITUTE(RIGHT(SUBSTITUTE(SUBSTITUTE( LEFT(CELL("filename";A20);FIND("]";CELL("filename";A20))-1);"[";"");"\";REPT(" ";300));600);REPT(" ";300);"\"))-1))

Ugniježđena formula 3 (autor osnovne formule AlKey)
=TRIM(RIGHT(SUBSTITUTE(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1);"\";REPT(" ";LEN(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1))));LEN(LEFT(CELL("filename";A1);FIND("[";CELL("filename";A1);1)-1))*2))

Ugniježđena formula 4 (fantastična kratka formula autora Rick Rothstein)
=TRIM(LEFT(RIGHT(SUBSTITUTE(CELL("filename";$A1);"\";REPT(" ";300));600);300))

Ugniježđena formula 5 (autor osnovne formule Aladin Akyurek)
=SUBSTITUTE(SUBSTITUTE(REPLACE(LEFT(CELL("filename";$A1);FIND("\[";CELL("filename";$A1)));1;FIND("#";
SUBSTITUTE(LEFT(CELL("filename";$A1);FIND("\[";CELL("filename";$A1)));"\";"#";LEN(LEFT(CELL("filename";$A1);
FIND("\[";CELL("filename";$A1))))-LEN(SUBSTITUTE(LEFT(CELL("filename";$A1);FIND("\[";CELL("filename";$A1)));"\";""))-1));"");"";"");"\";"")




   

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela