logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali -Vrati popis svih podataka iz jednog, dva ili više stupaca bez praznih ćelija, Vrati popis svih podataka iz jednog stupca ali bez praznih ćelija, Kopiraj podatke iz jednog stupca bez praznih ćelija, Spoji podatke iz dva stupca u jedan stupac

Prikaži popis svih podataka iz jednog, dva ili više stupaca




sponzor



Vrati popis svih podataka iz jednog stupca ali bez praznih ćelija

Jedan od čestih problema u Excelu je vraćanje popisa svih podataka ili vrijednosti iz jednog, dva ili više stupaca. Naravno želja nam je da lista bude bez praznih ćelija. U ovom prvom primjeru tutorijala proučite Excel formule koje koristimo za kopiranje podataka iz jednog stupca bez praznih ćelija.

Ako ste ikada imali potrebu prikazati popis svih podataka bez praznih ćelija a niste znali, pogledajte ovu kolekciju Excel formula. Sve formule vraćaju listu podataka iz 'A' stupca. Na slici ispod uočite podatke u 'A' stupcu. Tu se nalaze mješoviti podaci tekst i brojevi ili vrijednosti. Naš cilj je prikazati popis svih podataka bez praznih ćelija.

Kako prikazati popis svih podataka iz jednog stupca ali bez praznih ćelija

Na slici iznad uočite stupce koji prikazuju rezultate.

Formula u 'C' stupcu je slijedeća. (ova formula primjenjiva je u Excelu 2003 i novijem, formulu kopirajte u 'Formula Bar' jednu liniju koda)
=IF(ISERROR(INDEX(A:A;SMALL(INDEX(NOT(ISBLANK($A$2:$A$20))*ROW($A$2:$A$20);0);
COUNTBLANK($A$2:$A$20)+ROW(A1))));"";INDEX(A:A;SMALL(INDEX(NOT(ISBLANK($A$2:$A$20))*ROW($A$2:$A$20);0);
COUNTBLANK($A$2:$A$20)+ROW(A1))))

Formula u 'E2' ćeliji je slijedeća: (formulu kopirajte u 'Formula Bar' jednu liniju koda)
=IFERROR(INDEX(A:A;SMALL(INDEX(NOT(ISBLANK($A$2:$A$20))*ROW($A$2:$A$20);0);
COUNTBLANK($A$2:$A$20)+ROW(A1)));"")

ARRAY Formula (CSE) u 'G2' ćeliji je slijedeća: (formulu kopirajte u 'Formula Bar' jednu liniju koda)
=IFERROR(INDEX($A$2:$A$20;SMALL(IF(ISBLANK($A$2:$A$20)+ISERROR($A$2:$A$20);"";ROW($A$2:$A$20)-MIN(ROW($A$2:$A$20))+1);ROW(1:1)));"")

ARRAY Formula (CSE) u 'I2' ćeliji je slijedeća: (formulu kopirajte u 'Formula Bar' jednu liniju koda)
=IF(ROW()-ROW($I$2:$I$23)+1>ROWS($A$2:$A$20)-COUNTBLANK($A$2:$A$20);"";INDIRECT(ADDRESS( SMALL((
IF($A$2:$A$20<>"";ROW($A$2:$A$20);ROW()+ROWS($A$2:$A$20)));ROW()-ROW($I$2:$I$23)+1);COLUMN($A$2:$A$20);4)))

ARRAY Formula (CSE) u 'K2' ćeliji je slijedeća: (Ova CSE formula vraća jedinstvene podatke iz 'A' stupca bez praznih ćelija. Dakle oni podaci koji se u 'A' stupcu ponavljaju, prikazuju se samo jednom)
=IFERROR(INDEX($A$2:$A$20;MATCH(0;IF(LEN($A$2:$A$20);COUNTIF(K$1:K1;$A$2:$A$20);1);0));"")

Kako spojiti podatke iz dva stupca u jedan stupac

U koliko želite spojiti podatke iz dva stupca u jedan stupac ali tako da na popisu nema praznih ćelija tada proučite ovaj primjer ispod. Na slici ispod uočite dva stupca u kojem se nalaze podaci. Naš cilj je kopirati podatke iz dva stupca u jedan stupac, ali tako da se ne prikazuju prazne ćelije.

U 'A i B' stupcima uočite podatke koji nisu postavljeni u isti broj redova. Da bi kopirali podatke iz 'A i B' stupaca u 'F' stupac upotrijebiti ćemo 'helper' stupac u kojem imamo redne brojeve od 1 pa nadalje.

Spajanje podataka iz dva stupca u jedan stupac

Na slici iznad formula u 'F' stupcu je slijedeća: (uočite da ova formula kopira prvo podatke iz 'A' stupca pa zatim nastavlja sa kopiranjem podataka iz 'B' stupca. Napomena, ne smije biti praznih ćelija između prvog i zadnjeg podatka u izvornom stupcu.).
=IFERROR(IF($E$2:$E$11<=ROWS($A$2:$A$5);INDEX($A$2:$A$5;$E$2:$E$11);INDEX($B$2:$B$7;$E$2:$E$11-ROWS($A$2:$A$5)));"")

ARRAY formula (CSE) u 'H2' ćeliji radi isti posao kao i prethodna ali ne koristi 'helper' stupac.
=IFERROR(INDEX($A$2:$A$5;MATCH(0;IF(LEN($A$2:$A$5);COUNTIF(H$1:H1;$A$2:$A$5);1);0));IFERROR(INDEX($B$2:$B$7;
MATCH(0;IF( LEN($B$2:$B$7); COUNTIF(H$1:H1;$B$2:$B$7);1);0));""))

ARRAY formula (CSE) u 'K2' ćeliji vraća popis svih podataka kao i dvije prethodne formule, ali ne smije biti praznih ćelija između prvog i zadnjeg podatka u izvornom stupcu.
=IF(ROW(A1)<=COUNTA($A$2:$A$10);INDEX($A$2:$A$10;ROW(A1));IF(ROW(A1)>COUNTA($A$2:$B$10);"";
INDEX($B$2:$B$10;ROW(A1)-COUNTA($A$2:$A$10))))

Kopiranje podataka iz dva stupca u jedan koristeći dinamične raspone ćelija

Prethodni primjer iznad koristi apsolutne adrese u formulama. Ako imate potrebu dodavati podatke u izvorne stupce tada koristiti dinamične raspone ćelija. Dakle, ako želite imati dinamičan raspon ćelija tada raspone ćelija konvertirajte u Table1 i Table2 a u formuli koristite definirano ime umjesto apsolutnih adresa .

Prikazivanje svih podataka iz dva stupca u jednom stupcu korištenjem dinamičnog raspona ćelija

Na slici iznad korišteni su dinamični rasponi ćelija. Dva izvorna 'A' i 'B' stupca konvertirana su u Table1 i Table2 kao i pomoćni stupac koji je konvertiran u Table3.

Formula u 'F2' ćeliji je slijedeća:
=IFERROR(IF(Table3[helper]<=ROWS(Table1[Names1]);INDEX(Table1[Names1];Table3[helper]);INDEX(Table2[Names2]
;Table3[helper]-ROWS(Table1[Names1])));"")

Formula u 'H2' ćeliji je slijedeća:
=IFERROR(INDEX(Table1[Names1];MATCH(0;IF(LEN(Table1[Names1]);COUNTIF(H$1:H1;Table1[Names1]);1);0));
IFERROR(INDEX(Table2[Names2];MATCH(0;IF(LEN(Table2[Names2]);COUNTIF(H$1:H1;Table2[Names2]);1);0));""))

Prikaži popis svih podataka iz dva stupca u jednom stupcu sa CIK-CAK slijedom

Ako imate potrebu prikazati popis svih podataka iz dva stupca ali tako da slijed vraćenih podataka bude CIK-CAK raspored u jednom stupcu, tada proučite ovu formulu ispod. Dakle ova formula vraća podatke iz dva stupca ali tako da prvo vrati podatak iz prvog stupca pa zatim iz drugog stupca pa opet iz prvog stupca i tako redom.

ARRAY (CSE) formula u 'D2' ćeliji na slici ispod je slijedeća:
=INDEX($A$2:$B$7;INT((ROWS(D$3:D3)-1)/2)+1;MOD(ROWS(D$3:D3)-1;2)+1)

Popis teksta i vrijednosti iz dva stupca u jednom stupcu

Kako kopirati podatke iz tri stupca u jedan stupac

Kada imamo situaciju kopiranja ili prikaza podataka iz tri stupca u jednom stupcu, tada možete proučiti primjer ispod. Na slici ispod uočite višestruke stupce koji sadrže podatke (tekst i vrijednosti). Naš cilj je prikaz svih podataka u jednom stupcu.

Formula u 'E1' ćeliji je slijedeća:
=IF(ROW()<=COUNTA(A:A);INDEX(A:A;ROW());IF(ROW()<=COUNTA(A:B);INDEX(B:B;ROW()-COUNTA(A:A));IF(ROW()>COUNTA(A:C);"";INDEX(C:C;ROW()-COUNTA(A:B)))))

Vrati podatke iz tri stupca u jedan stupac


Prikaži popis iz višestrukih stupaca u jedan stupac

U drugom slučaju imamo drugačiju formulu koja će ignorirati prazne ćelije i vratiti sve podatke iz višestrukih stupaca u jedan stupac.

Formula u 'E2' ćeliji na slici ispod je slijedeća:
=IFERROR(INDEX($A$2:$A$17;MATCH(0;IF(LEN($A$2:$A$17);COUNTIF(E$1:E1;$A$2:$A$17);1);0));
IFERROR(INDEX($B$2:$B$17;MATCH(0;IF(LEN($B$2:$B$17);COUNTIF(E$1:E1;$B$2:$B$17);1);0));
IFERROR(INDEX($C$2:$C$17;MATCH(0;IF(LEN($C$2:$C$17);COUNTIF(E$1:E1;$C$2:$C$17);1);0));"")))

Vrati sve podatke iz višestrukih stupaca u jedan stupac bez praznih ćelija

Naravno, vi uvijek možete konvertirati raspon ćelija izvornih stupaca u Table1, Table2 i Table3 da bi imali promjenjiv raspon ako dodajete podatke u izvornim stupcima.

U prilogu ovog Excel tutorijala imate mogućnost Download ZIP datoteke
(Kopiraj sve podatke iz više stupaca u jedan stupac) u kojoj se nalazi Workbook koju sam koristio prilikom izrade ovog tutorijala.




     

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela