logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali - Kopiranje svake N-te ćelije, Copy every Nth cell or each N-th value from same Row or Column in Excel, Return every Nth cell or value, Označi bojom svaki drugi red ili svaku treću ćeliju u stupcu, Display each Nth cell from Row or Column

Kopiraj i grupiraj svaku N-tu ćeliju




sponzor



Copy and group every Nth cell or each N-th value

Ovaj tutorijal opisuje razne načine kopiranja svake N ćelije u nekakvom kontinuiranom razmaku. Ako tražite neki od navedenih pojmova ispod tada nastavaite čitati tutorijal.

  • Kako kopirati svaku treću ili četvrtu ćeliju iz stupca
  • Kako kopirati svaku petu ćeliju iz reda
  • Kako prikazati vrijednost ili podatak iz svake sedme ili desete ćelije
  • Kopiranje svake treće vrijednosti

Kako kopirati svaku N-tu ili petu (treću, sedmu, desetu itd...) ćeliju iz istog reda

U ovom prvom primjeru pogledajte situaciju na slici ispod. Za uvećanje slike kliknite na sliku.

Kako kopirati svaku N ćeliju u istom redu

Situacija na slici iznad je slijedeća. U drugom i trećem redu imamo vrijednosti (podatke) koje želimo kopirati ali pod uvjetom. U ovom slučaju želimo kopirati svaku petu vrijednost (ili ćeliju) iz redova. Uz ovo kopiranje svake 5-te ćelije automatski grupiramo sve vrijednosti. Evo nekoliko formula koje kopiraju svaku N vrijednost

Formula u ćeliji C5 je slijedeća: (Formulu kopirajte u desnu stranu). Ova formula kopira prvu vrijednost koja se nalazi u ćeliji G2 na slici označeno crvenom bojom.

=IF(OFFSET($A2;;COLUMN(A:A)*5+1)=0;"";OFFSET($A2;;COLUMN(A:A)*5+1))

Formula u ćeliji C6 je slijedeća: (Formulu kopirajte u desnu stranu). Ova formula kopira prvu vrijednost koja se nalazi u ćeliji L3 na slici označeno crvenom bojom.

=IF(OFFSET($A3;;COLUMN(B:B)*5+1)=0;"";OFFSET($A3;;COLUMN(B:B)*5+1))

U formulama iznad uočite da se razlikuju po tome što je prva formula započela u A stupcu a druga formula je započela u B stupcu.

Formula u ćeliji C8 je slijedeća: (Formulu kopirajte u desnu stranu). Ova formula kopira prvu vrijednost koja se nalazi u prvoj ćeliji C2.

=OFFSET($A2;;COLUMN(A:A)*5-3)

Formula u ćeliji C9 je slijedeća: (Formulu kopirajte u desnu stranu). Ova formula kopira prvu vrijednost koja se nalazi u prvoj ćeliji C3.

=IF(OFFSET($A3;;COLUMN(A:A)*5-3)="";"";OFFSET($A3;;COLUMN(A:A)*5-3))

Primjer kako zbrojiti svaku N-tu vrijednost u istom redu

Ako trebate zbrojiti vrijednosti iz svake N ćelije u istom redu, iskoristite ovu formulu ispod. Formula ispod zbraja svaku treću vrijednost u istom redu, prva vrijednost nalazi se u ćeliji C2.

Formula u ćeliji C11 je slijedeća:

=SUMPRODUCT(--(MOD(COLUMN(C2:AG2);3)=MOD(COLUMN(C1);3));(C2:AG2))

Kopiranje svake četvrte (4-te) vrijednosti ili ćelije iz istog stupca

U ovom drugom primjeru na slici ispod, uočite kako kopirati svaku N vrijednost ili ćeliju iz istog stupca. U ovom slučaju mi želimo kopirati svaku četvrtu vrijednost ili ćeliju. Ima nekoliko načina rješavanja ovog problema, pogledajte formule ispod slike.

Kopiranje svake četvrte vrijednosti ili ćelije iz istog stupca

Formula u ćeliji C2 na slici iznad je slijedeća: Ova formula prikazuje vrijednost iz prve ćelije iz koje želimo vratiti N vrijednost. Ova formula služi kao prethodnica slijedećoj formuli ispod u C3.

=A7

Formula u ćeliji C3 na slici iznad je slijedeća: Uočite u formuli broj 4, ovaj broj predstavlja svaku četvrtu ćeliju.

=OFFSET($A$7;ROW(A1)*4;0)

Formula u ćeliji H2 na slici iznad je slijedeća: Uočite u formuli broj 4, ovaj broj predstavlja svaku četvrtu ćeliju, raspon A7:A25 određuje poziciju prve N-te ćelije koju želimo prikazati.

=INDEX($A$7:$A$25;4*(ROWS($A$2:A2)-1)+1)

Formula u ćeliji J2 na slici iznad je slijedeća: Formula kao prvu ćeliju vraća vrijednost iz A2. Uočite u formuli broj 4, ovaj broj predstavlja svaku četvrtu ćeliju, raspon ROWS(J$1:J1) određuje stupac i red u kojem se nalazi ova formula.

=INDEX(A$1:A$21;4*ROWS(J$1:J1)-2)

Formula u ćeliji L2 na slici iznad je slijedeća: Ova formula prikazuje isti rezultat kao i prethodna. Formula kao prvu ćeliju vraća vrijednost iz A2. Uočite u formuli broj 4, ovaj broj predstavlja svaku četvrtu ćeliju, raspon ROW(A1)-1 određuje red u kojem se nalazi ova formula.

=IF(A2>0;OFFSET($A$2;(ROW(A1)-1)*4;0);A2)

Kako prikazati ili kopirati svaku treću (3-ću) ili N-tu vrijednost ili ćeliju iz Excel stupca

U ovom primjeru ovog tutorijala prikazat ću enkoliko formula autora 'cpearson' pomoću kojih možete kopirati svaku treću ili Ntu vrijednost iz stupca. Uočite situaciju na slici ispod.

Display or copy every N value or cell from Column

ARRAY formula u ćeliji F2 na slici iznad je slijedeća: Ova formula prikazuje prvu vrijednost koju želimo kopirati iz stupca 'A'. Uočite da se u formuli koristi apsolutna adresa ćelije u kojoj se nalazi formula. Broj 3 u formuli znači da kopiramo svaku treću vrijednost iz stupca A.

=IF((ROW()-ROW($F$2))*3>=(ROWS($A$2:$A$21));"";OFFSET($A$2:$A$21;(ROW()-ROW($F$2))*3;0;1;1))

ARRAY formula u ćeliji H2 na slici iznad je slijedeća: Ova formula prikazuje prvu vrijednost koju želimo kopirati iz stupca 'A'. Uočite da se u formuli koristi apsolutna adresa ćelije u kojoj se nalazi formula. Broj 3 u formuli znači da kopiramo svaku treću vrijednost iz stupca A. Broj 1 (označen crvenom bojom) označava broj startnog reda u kojem se nalazi prva ćelija koju želimo kopirati.

=IF((ROW()-ROW($H$2))*3>=(ROWS(OFFSET($A$2:$A$21;1-1;0)));"";OFFSET(OFFSET($A$2:$A$21;1-1;0);(ROW()-ROW($H$2))*3;0;1;1))

sponzor


U koliko želite prebrojiti koliko se puta pojavljuje svaka treća ćelija u određenom rasponu ćelija tada iskoristite slijedeću formulu u stupcu 'J'.

Formula u ćeliji J2 na slici iznad je slijedeća: Formula u J10 je funkcija SUM.

=COUNTIF(OFFSET($A$2;(ROW(A1)-1)*3;0);">=1")

Ako želite zbrojiti svaku treću ćeliju sa prikazanim vrijednostima tada iskoristite slijedeću formulu u stupcu 'K'.

Formula u ćeliji K2 na slici iznad je slijedeća: Formula prikazuje svaku treću ćeliju i vrijednost koji dotična ćelija sadrži. Formula u K10 je funkcija SUM.

=INDIRECT("A"&(ROW(A1)-1)*3+2)

Ako želite u jednoj ćeliji prikazati SUM svih vrijednosti iz svake treće (3-će) ćelije u stupcu 'A' tada iskoristite slijedeću formulu.

ARRAY formula u ćeliji D2 na slici iznad je slijedeća: Broj 1 označen crvenom bojom je startni red a broj 3 je interval za svaku treću ćeliju.

=SUM(IF(MOD(ROW(OFFSET(A2:A21;1-1;0))-ROW(OFFSET(OFFSET(A2:A21;1-1;0);0;0;1;1));3)=0;OFFSET(A2:A21;1-1;0);0))

Drugi način zbrajanja svake treće ćelije u stupcu nalazi se u ćeliji 'D3'.

ARRAY formula u ćeliji D3 na slici iznad je slijedeća:

=SUM(IF(MOD(ROW($A$2:$A$21)-ROW(A2);3)=0;$A$2:$A$21;0))

Prosjek zbroja svih vrijednosti svake treće ćelije iz stupca

U koliko želite izračunati prosjek zbroja svih vrijednosti svake treće ćelije tada iskoristite slijedeću formulu (autor formule cpearson.com). Broj 1 označen crvenom bojom je startni red a broj 3 je interval za svaku treću ćeliju.

=AVERAGE(IF(MOD(ROW(OFFSET($A$2:$A$21;1-1;0))-ROW(OFFSET(OFFSET($A$2:$A$21;1-1;0);0;0;1;1));3)=0;OFFSET($A$2:$A$21;1-1;0);FALSE))

 

Slična tema vezana za kopiranje N vrijednosti ili ćelije: Copy and Transpose every Nth cell or value
Ako želite možete pogledati ostale teme vezane za kopiranje u Excelu: Teme i tutorijali za kopiranje u Excelu

   

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela