logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCE 2013 tutoriali - INDIRECT function, Excel INDIRECT function tutorial, Indirect Excel funkcija, Referenciranje na određenu Excel ćeliju na drugom radnom listu, Kako referencirati ime radnog lista u formuli koja koristi INDIRECT funkciju, Kopiranje podataka sa višestrukih radnih listova koristeći INDIRECT funkciju

Excel INDIRECT function




sponzor



Indirect Excel funkcija

Excel funkcija INDIRECT kao rezultat vraća adresu kad je upisana kao tekst, dakle vraća referencu navedenu tekstnim nizom. Reference su odmah vrednovane za prikaz njihova sadržaja. Koristite INDIRECT kada želite promijeniti referencu na ćeliju u formuli, bez promjene same formule.

NAPOMENA: INDIRECT funkcija spada u grupu "problematičnih/hlapljivih" funkcija (Volatile Functions)

Sintaksa

INDIRECT(ref_text;a1)

Ref_text je referenca prema ćeliji koja sadrži referencu stila A1, referencu stila R1C1, naziv koji je određen kao referenca ili referencu prema ćeliji kao tekstni niz. Ako ref_text nije ispravna referenca ćelije, INDIRECT će prikazati vrijednost pogreške #REF!.

  • Ako ref_text upućuje na drugu radnu knjigu (vanjska referenca), druga radna knjiga mora biti otvorena. Ako izvorna radna knjiga nije otvorena, INDIRECT vraća vrijednost pogreške #REF!.

A1 je logička vrijednost koja određuje koja vrsta reference je sadržana u ćeliji ref_text.

  • Ako je a1 TRUE ili ga nema, ref_text se smatra referencom stila A1.
  • Ako je a1 FALSE, ref_text se smatra referencom stila R1C1.

Da bi shvatili kako radi funkcija INDIRECT, pokazat ću vam na jednostavnim primjerima. Vjerojatno će se netko pitati zašto nisam postavio primjer Workbook iz ovog tutorijala. Ja nemam taj običaj, moje mišljenje je da korisnik Excela najbolje može naučiti kada sam ručno unosi podatke i formule u radni list. Zato, ja savjetujem, prvo pročitajte ovaj tutorijal i ako vam je interesantan i želite naučiti više, tada otvorite vaš Excel program i korak po korak pratite tutorijal, tokom praćenja ručno unosite podatke i formule u vašu Workbook.

Prvi primjer funkcije INDIRECT

U stupcu 'A' imamo podatke. U ćeliji 'D7' nalazi se broj 3. U ćeliji 'C1' imamo formulu =INDIRECT(A3). Dakle ova formula sa funkcijom INDIRECT referencira se na ćeliju 'A3'. U ćeliji 'A3' imamo tekstualnu oznaku 'D7' što je u stvari relativna adresa ćelije 'D7'. Dakle formula se referencira na ćeliju A3 i na osnovu njenog podatka povlači broj iz ćelije koju je referencirala ćelija 'A3' a to je broj iz ćelije 'D7'. (vidi sliku ispod)

INDIRECT Excel funkcija

Naravno mi smo mogli u ćeliji 'C1' kreirati formulu =D7 ali to nije dobro. Zašto?

Zato što bi u slučaju dodavanja novog reda iznad sedmog retka naša formula vratila opet isti rezultat a to je broj 3. Ne, mi to ne želimo. Mi želimo da nam formula uvijek vrati rezultat iz fiksne ćelije 'D7'. Probajte selektirati Row6 i umetnite novi red iznad. Broj 3 će se pomjeriti prema dolje a dotična formula nakon umetanja novog reda promijenit će formulu u 'D8' i rezultat će biti i dalje broj 3. Dakle, Kada dodate novi red sve formule koje su u vezi sa dotičnim rangom mijenjaju svoje izvorne adrese. Ako koristite INDIRECT funkciju sa referencom na ćeliju npr. A3, Excel će i nakon dodanog reda iznad referencirati se na ćeliju koja je postavljena u 'A3'. Također, dotičnu formulu =INDIRECT(A3) možemo unijeti kao =INDIRECT("D"&7) ili =INDIRECT("D7") da bi izbjegli referenciranje na ćeliju 'A3'.

Drugi primjer INDIRECT funkcije

U ovom drugom primjeru na slici ispod uočite različite izvedbe formula koristeći INDIRECT funkciju. U slučaju da je ćelija prazna (G5, G6 ili G7) formula vraća grešku "REF!. Da bi izbjegli ovu grešku koristite IF funkciju.

U ćeliji 'H5' nalazi se formula =INDIRECT(G5), ova formula vraća podatak iz ćelije 'A3'.
U ćeliji 'H6' nalazi se formula =INDIRECT(G6;FALSE), ova formula vraća podatak iz ćelije 'Row 4 i Column1' => 'A4'.
U ćeliji 'H7' nalazi se formula =INDIRECT("A"&G7), ova formula vraća podatak iz ćelije 'A9'.

primjeri Excel INDIRECT funkcije

Treći primjer - Kako referencirati ime radnog lista u formuli koja koristi INDIRECT funkciju

U ovom primjeru uočite tri radna lista. Na radnom listu 'Sheet2' postavljena je formula. U stupcu 'A' nalazi se popis radnih listova a u stupcu 'B' nalaze se adrese ćelija iz kojih povlačimo podatke sa dotičnih radnih listova.

Formula u ćeliji 'D1' je =INDIRECT("'"&A1&"'!"&B1), ovu formulu možemo također unijeti kao =INDIRECT("'"&A1&"'!"&"A2")
Formula u ćeliji 'D2' je =INDIRECT("'"&A2&"'!"&B2), ovu formulu možemo također unijeti kao =INDIRECT("'"&A2&"'!"&"F3")
Formula u ćeliji 'D3' je =INDIRECT("'"&A3&"'!"&B3), ovu formulu možemo također unijeti kao =INDIRECT("'"&A3&"'!"&"A1")

Sve navedene formule na osnovu podataka iz 'A i B' stupca/ćelija povlače podatke iz dotičnih adresa ćelija na radnim listovima. Da bi vam bilo jasnije npogledajte "Evaluate formula" korak po korak.

Referenciranje imena radnog lista u Excelu upotrebom INDIRECT funkcije

Kopiranje podataka sa višestrukih radnih listova koristeći INDIRECT funkciju

U ovom primjeru za Indirect funkciju pokazati ću kako možemo kopirati ili prikazati podatke pomoću jedne formule sa višestrukih radnih listova. Na slici ispod uočite nazive radnih listova sa kojih kopiramo podatke na 'master' radni list. Svi ostali radni listovi imenovani su datumom u mjesecu. Tako radni list '1' definira prvi datum u mjesecu, radni list '2' definira drugi dan u mjesecu itd. Ja sam prikazao 4 radna lista, naravno mjesec može imati do 31 da pa tako i radna knjiga može sadržavati 31 radni list.

U prvom retku na 'master' radnom listu uočite brojeve 1,2,3,4, a može ih biti do ...31. Ovi brojevi identični su nazivima radnih listova jer jedan mjesec sadrži do 31 dan. Zašto je to baš tako vidjet ćete kasnije u toku praćenja ovog tutorijala. Naravno, mi možemo imati i drugačije nazive radnih listova u zaglavlju, ali ovaj primjer ja sam zamislio ovako.

Kao prvo idemo vidjeti koja je osnovna formula za prikazivanje podataka sa drugog radnog lista. Uočite na slici ispod da je to jednostavna formula koja je linkana na određenu ćeliju ='1'!D9 (ili ova formula ='1'!$D9)

Znači, ova formula povlači podatak iz radnog lista imena '1' iz ćelije 'D9'. Ova formula je u redu ako kopiramo prema dolje. Međutim, problem nastaje kada formulu kopiramo u desnu stranu. Formula prilikom kopiranja u desno, mijenja se u ='1'!E9, ='1'!F9 itd. i vraća neispravan rezultat. Ako fiksiramo adresu stupca 'D' (='1'!$D9) tada formula vraća jedan te isti rezultat. Ovo nije dobro za naše rezultate jer se izmjenjuje ili fiksira adresa ćelije iz koje želimo povući podatak. Morali bi u drugom redu u svakom stupcu izmjeniti sve formule a njih je tridesetjedna formula.

Kopiranje podataka sa višestrukih radnih listova u Excel Workbook

Da bi izbjegli izmjenu adrese ćelije prilikom kopiranja u desnu stranu koristiti ćemo INDIRECT funkciju i kreirati formulu.

=INDIRECT("'"&A$1&"'!$"&"D"&ROW(D9))

Formula koja se nalazi iznad vraća podatak iz ćelije 'D9' sa radnog lista imenovanog '1'. Ovdje do izražaja dolazi zašto sam sve radne listove imenovao brojevima datuma u mjesecu. Zato što prilikom kopiranja u desnu stranu koristim podatke u ćelijama koje se nalaze u prvom retku (Row1) a to su nazivi radnih listova.

Pokušat ću vam objasniti. Dakle ova formula se nalazi u ćeliji 'A2'. =INDIRECT("'"&A$1&"'!$"&"D"&ROW(D9)). Ovu formulu također možemo unijeti kao =INDIRECT("'"&A$1&"'!$"&"D"&ROW(9:9))

Kada ovu formulu kopiram u desnu stranu ona se mijenja u slijedeće:

B2: =INDIRECT("'"&B$1&"'!$"&"D"&ROW(E9))
C2: =INDIRECT("'"&C$1&"'!$"&"D"&ROW(F9))
D2: =INDIRECT("'"&D$1&"'!$"&"D"&ROW(G9))
itd.

Dakle, uočite kako se prilikom kopiranje u desnu stranu mijenja samo oznaka stupca. Ovdje nemojte obraćati pažnju na funkciju ROW(D9) ili ROW(9:9) jer nam ona nije važna prilikom kopiranja formule u desnu stranu.

Objašnjenje formule INDIRECT

Ja ću pokušati objasniti formulu iznad . Na ribonu "Formulas" tab nalazi se naredba "Evaluate formula". Kada vi selektirate ćeliju u kojoj se nalazi formula i pokrenete "Evaluate Formula" vi možete vidjeti korak po korak tok izračuna formule.

  1. =INDIRECT("'"&A$1&"'!$"&"D"&ROW(D9))
  2. =INDIRECT("'"&1&"'!$"&"D"&ROW(D9))
  3. =INDIRECT("'1"&"'!$"&"D"&ROW(D9))
  4. =INDIRECT("'1'!$"&"D"&ROW(D9))
  5. =INDIRECT("'1'!$D"&ROW(D9))
  6. =INDIRECT("'1'!$D"&9)
  7. =INDIRECT("'1'!$D9")
  8. =Joan

Kopiranje INDIRECT formule u desnu stranu

Dakle, uočite ovaj važan dio formule "'"&A$1&"'!$"

Ovaj dio formule povlači podatak iz stupca 'A' i ćelije '1' . Kada cijelu formulu kopiramo u desnu stranu slovo 'A' koje označava stupac mijenja se u B, C, D... . Kopiranjem formule u desnu stranu mi mijenjamo naziv radnog lista a redak ostaje isti.

  • A2: "'"&A$1&"'!$" rezultat je 'A$1'!$ => 'A$1'!$D&D9 => '1'!$D9
  • B2: "'"&B$1&"'!$" rezultat je 'B$1'!$ => 'B$1'!$D&D9 => '2'!$D9
  • C2: "'"&C$1&"'!$" rezultat je 'C$1'!$ => 'C$1'!$D&D9 => '3'!$D9
  • D2: "'"&D$1&"'!$" rezultat je 'D$1'!$ => 'D$1'!$D&D9 => '4'!$D9
  • ....

Naravno još nam ostaje drugi dio formule a to je ROW(D9) ili ROW(9:9) koji spajanjem čini cjelovitu formulu u završetku izračuna. Također uočite da prilikom kopiranja formule u desnu stranu, mijenja se i adresa ćelije ROW(D9) funkcije. Ova izmjena nema utjecaja na završnu formulu jer je uvijek definiran deveti redak, to i jeste naš cilj.

Kopiranje INDIRECT formule dolje

Kopiranjem formule prema dolje mi mijenjamo broj reda a naziv radnog lista ostaje isti.

Dotična formula kopiranjem prema dolje mijenja broj reda, stupac i adresa ćelije u prvom redu ostaje nepromijenjena.
Primjer za stupac 'A'

  • A2: "'"&A$1&"'!$"&"D"&ROW(D9) rezultat je '1'!$D9
  • A3: "'"&A$1&"'!$"&"D"&ROW(D10) rezultat je '1'!$D10
  • A4: "'"&A$1&"'!$"&"D"&ROW(D11) rezultat je '1'!$D11
  • ...

I na kraju finalno objašnjenje.

Formula kopiranjem u desnu stranu, vraća podatak iz ćelije D9 iz radnih listova koji su određeni brojem u prvom redu.
Formula kopiranjem prema dolje, vraća podatak iz ćelije D9, D10, D11... iz radnih listova koji su određeni brojem u prvom redu.

sponzor


Više primjera možete pogledati na tutorijalu INDIRECT funkcija s primjerima .
Također pogledajte funkciju INDIRECT.EXT koja radi sa zatvorenim radnim knjigama.




   

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela