logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali -HYPERLINK u Excelu, Excel HYPERLINK u istoj radnoj knjizi, Kako kreirati link u istoj radnoj knjizi u Excelu, Hyperlink na drugi radni list iste Workbook, Link na ćeliju u drugoj radnoj knjizi ili datoteci

Excel HYPERLINK u istoj radnoj knjizi




sponzor



HYPERLINK u Excelu

Nastavak pregleda tutorijala za temu HYPERLINK u Excelu. U ovom dijelu tutorijala obratite pažnju na ćelije A14:A27 u kojima se nalazi kreirani HYPERLINK.

Hyperlink ili Link u Excelu

Na slici iznad nalaze se primjeri kreiranih hiperlinkova u Excelu za razne situacije bilo da u ćelijama imamo uvjet ili kriterij ili da direktno postavljamo adresu linka.

NAPOMENA: Ako kopirate formule sa ove web stranice tutorijala tada obratite pažnju da formula bude u jednom retku ili jednoj liniji.

Excel ćelija A14 na slici iznad:
Hyperlink u kojem točno definiramo radnu knjigu, radni list i adresu ćelije
Rezultat formule je Hyperlink na Sheet2 u ćeliju A1 u istoj radnoj knjizi: Link na Sheet2 u ćeliju A1 u istoj Workbook. Uočite da je definirana radna knjiga Book1.xlsx koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je:=HYPERLINK("[Book1.xlsx]"&"Sheet2!"&"A1";"Link na Sheet2 u ćeliju A1 u istoj Workbook")

Excel ćelija A15 na slici iznad:
Hyperlink u kojem točno definiramo radnu knjigu, radni list i adresu ćelije. Ova formula ili hyperlink nalazi se u radnoj knjizi Book1.xlsx a putanja otvaranja je radna knjiga Book7.xlsx
Kada kliknemo na hyperlink Excel će otvoriti radnu knjigu Book7.xlsx i pozicionirati se na radni list 'AB' u ćeliju 'A9' (ali samo ako se obe radne knjige nalaze u istom folderu.
Rezultat formule je Hyperlink tekst na radni list 'AB' u ćeliju A9 u radnoj knjizi Book7.xlsx:
Link na Sheet AB u ćeliju A9 u Workbook Book7.xlsx
Uočite da je definirana radna knjiga Book7.xlsx koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je:=HYPERLINK("[Book7.xlsx]"&"AB!"&"A9";"Link na Sheet AB u ćeliju A9 u Workbook Book7.xlsx")

Excel ćelija A17 na slici iznad:
Hyperlink u kojem točno definiramo radnu knjigu, uvjet za radni list nalazi se u ćeliji 'B17' a target adresa je imenovana ćelija imenom 'prodaja'. Ova formula ili hyperlink nalazi se u radnoj knjizi Book1.xlsx
Kada kliknemo na hyperlink Excel će se pozicionirat na radni list iz ćelije B17 koja je uvjet u ćeliju koja je imenovana naziovom 'prodaja'
Rezultat formule je Hyperlink tekst na drugi radni list uz uvjet u imenovanu ćeliju iste radne knjige.
Link na imenovanu ćeliju 'prodaja' u istoj Workbook uz uvjet u B17
Uočite da je definirana radna knjiga Book1.xlsx koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je:=HYPERLINK("[Book1.xlsx]"&B17&"!"&"Prodaja";"Link na imenovanu ćeliju 'prodaja' u istoj Workbook uz uvjet u B17")

Excel ćelija A18 na slici iznad:
Hyperlink u kojem točno definiramo radnu knjigu, radni list, a target adresa je imenovana ćelija imenom 'prodaja'. Ova formula ili hyperlink nalazi se u radnoj knjizi Book1.xlsx a putanja otvaranja je radna knjiga Book7.xlsx
Kada kliknemo na hyperlink Excel će otvoriti radnu knjigu Book7.xlsx i pozicionirati se na radni list 'ABC' u ćeliju koja je imenovana 'prodaja' (ali samo ako se obe radne knjige nalaze u sitom folderu).
Rezultat formule je Hyperlink tekst na radni list 'AB' u ćeliju A9 u radnoj knjizi Book7.xlsx:
Link na imenovanu ćeliju 'prodaja' na Sheetu ABC u Book7.xlsx
Uočite da je definirana radna knjiga Book7.xlsx koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je: =HYPERLINK("[Book7.xlsx]"&"ABC!"&"Prodaja";"Link na imenovanu ćeliju 'prodaja' na Sheetu ABC u Book7.xlsx")

Općenito radi se o formulama HYPERLINK koje mogu izgledati kao formule ispod.

=HYPERLINK("[Book.xlsx]"&"Sheet2!"&"$A$1";"Tekst Linka")
=HYPERLINK("[Book.xlsx]"&"AB!"&"A1";"Link na Sheet AB u ćeliju A1")
=HYPERLINK("[Book.xlsx]"&"SheetName"&"!"&"CellAddressPosition";"tekst_linka")
=HYPERLINK("[Book.xlsx]"&"SheetName!"&"CellAddressPosition";"Link na Sheet AB u ćeliju A1 u Workbook Book7.xlsx")

Excel ćelija A20 na slici iznad:
Hyperlink u kojem točno definiramo samo ćeliju na koju se želimo pozicionirati nakon klika na hyperlink.
Rezultat formule je Hyperlink tekst na aktivni radni list u ćeliju 'A1' u aktivnoj radnoj knjizi:
Link na ćeliju A1 na aktivnom Sheetu
Uočite da je nije definirana aktivna radna knjiga već nju određuje znak ljestvice (sharp ili hash) a radni list postavlja formula (zelena slova) koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je: =HYPERLINK("#"&"'"&MID(CELL("filename";A1);FIND("]";CELL("filename";A1))+1;256)&"'!"&"A1";"Link na ćeliju A1 na aktivnom Sheetu")

Excel ćelija A21 na slici iznad:
Hyperlink u kojem pomoću Excel funkcije Concatenate definiramo radnu knjigu, radni list čije ime se nalazi u ćeliji B21 i destinacijsku ćeliju 'A1'.
Rezultat formule je Hyperlink tekst na aktivni radni list u ćeliju 'A1' u aktivnoj radnoj knjizi:
Link na Sheet3 na A1 ćeliju uz uvjet iz B21
Uočite da je nije definirana aktivna radna knjiga već nju određuje znak ljestvice (sharp ili hash) a radni list postavlja formula (zelena slova) koja je spojena sa nazivom radnog lista i ćelijom 'A1'.
Formula je: =HYPERLINK(CONCATENATE("#";B21;"!";"A1");"Link na Sheet3 na A1 ćeliju uz uvjet iz B21")

Općenito radi se o formulama HYPERLINK koje mogu izgledati kao formule ispod.

=HYPERLINK("#"&"'"&MID(CELL("filename";A1);FIND("]";CELL("filename";A1))+1;256)&"'!"&"A1";"LinkName")
=HYPERLINK("#"&"'"&
MID(CELL("filename";A1);FIND("]";CELL("filename";A1))+1;256)&"'!"&"CellAddressPosition";"LinkName")

Formula ispod koristi definirano ime za određenu formulu
=HYPERLINK(MySheet&ADDRESS(MATCH(adresa_ćelije_u_kojoj_se_nalazi_uvjet
;$A$1:$A$100;0);1)
;adresa_ćelije_u_kojoj_se_nalazi_uvjet&" tekst-link ")

U Name Manageru potrebno je definirati ime MySheet.
U polje Refers to: =MID(CELL("filename";A!$A$1);FIND("[";CELL("filename";A!$A$1));256)&"!"

Excel ćelija A23 na slici iznad:
Hyperlink u kojem znak ljestvice (sharp, pound ili hash) određuje aktivnu radnu knjigu, radni list direktno definiramo spajanjem teksta, kao i destinacijsku ćeliju 'D7' koju određujemo adresom ćelije.
Rezultat formule je Hyperlink tekst na radni list 'Sheet2' u ćeliju 'D7' u aktivnoj radnoj knjizi:
Link na Sheet2 u ćeliju D7 iste Workbook
Uočite da je nije definirana aktivna radna knjiga već nju određuje znak ljestvice (hash) a radni list postavlja izraz ili string (zelena slova) koja je spojena u naziv radnog lista.
Formula je: =HYPERLINK("#"&"'"&"Sheet2"&"'!"&"D7";"Link na Sheet2 u ćeliju D7 iste Workbook")

Excel ćelija A24 na slici iznad:
Hyperlink u kojem znak ljestvice (sharp, pound ili hash) određuje aktivnu radnu knjigu, radni list direktno definiramo preko uvjeta u ćeliji B24, a destinacijsku ćeliju 'D7' postavljamo adresom Excel ćelije.
Rezultat formule je Hyperlink tekst na radni list 'Sheet2' u ćeliju 'D7' u aktivnoj radnoj knjizi:
Link na Sheet2 u ćeliju D7 iste Workbook uz uvjet u B24
Uočite da je nije definirana aktivna radna knjiga već nju određuje znak ljestvice (hash) a radni list postavlja izraz ili string (zelena slova) koja je spojena sa nazivom radnog lista iz 'B24'.
Formula je: =HYPERLINK("#"&"'"&B24&"'!"&"D7";"Link na Sheet2 u ćeliju D7 iste Workbook uz uvjet u B24")

Excel ćelija A25 na slici iznad:
Hyperlink u kojem znak ljestvice (sharp, pound ili hash) određuje aktivnu radnu knjigu, radni list definiramo preko Excel funkcije INDIRECT koja sadrži uvjet iz ćelije B25, a destinacijsku ćeliju 'D7' postavljamo adresom Excel ćelije. (pogledajte prethodni tutorijal za funkciju INDIRECT i koji rezultat vraća, klikom na BACK button pri kraju ovog tutorijala)
Rezultat formule je Hyperlink tekst na radni list 'Sheet2' u ćeliju 'D7' u aktivnoj radnoj knjizi:
Link u ćeliju D7 na Sheet2 u istoj Workbook čiji se naziv nalazi u B25 kao uvjet
Uočite da je nije definirana aktivna radna knjiga već nju određuje znak ljestvice (hash) a radni list postavlja izraz ili string (zelena slova) koja je spojena sa nazivom radnog lista iz 'B25'.
Formula je: =HYPERLINK("#"&"'"&INDIRECT("B25")&"'!"&"D7";"Link u ćeliju D7 na Sheet u istoj Workbook čiji se naziv nalazi u B25 kao uvjet")

Excel ćelija A27 na slici iznad:
Ime 'MySheet' određuje aktivnu radnu knjigu i radni list ,target ćeliju određujemo preko Excel funkcije ADDRESS/MATCH koja sadrži uvjet iz ćelije B27 (pogledajte prethodni tutorijal za ovu formulu i koji rezultat vraća, klikom na BACK button pri kraju ovog tutorijala) .
Rezultat formule je Hyperlink tekst na radni list 'Sheet1' u prvu ćeliju koja sadrži tekst ili string 'XYZ' u aktivnoj radnoj knjizi:
XYZ Link
Formula je:=HYPERLINK(MySheet&ADDRESS(MATCH(B27;$A$1:$A$102;0);1);B27&" Link")

U Name Manageru potrebno je definirati novo ime MySheet.
U polje Referst to: =MID(CELL("filename";Sheet1!$A$1);FIND("[";CELL("filename";Sheet1!$A$1));256)&"!"

Name Manager u Excelu

sponzor


Općenito radi se o formulama HYPERLINK koje mogu izgledati kao formule ispod.

=HYPERLINK("#"&"'"&"AB"&"'!"&"D7";"Link na Sheet AB u ćeliju D7 iste Workbook")
=HYPERLINK("#"&"'"&"SheetName"&"'!"&"CellAddressPosition";"LinkName")
=HYPERLINK("#"&"'"&INDIRECT("A33")&"'!"&"D7";"naziv sheeta AB se nalazi u ćeliji A33 a linka se u ćeliju D7 SheetAB iste Workbook")
=HYPERLINK(MySheet&destinacijska_ćelija;uvjet&" text ")

Razni tutorijali vezani za tematiku HYPERLINK u Excelu

Za nastavak pregleda tutorijala kliknite na NEXT button.




  Prethodna stranica tutorijala Slijedeća stranica tutorijala

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela