logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL tutoriali - Kako koristiti šifriranje ili kriptografiju u Excelu, Enigma šifriranje u Excelu, Kodiranje ili kriptografija u Excelu, Kako uradiit enkripciju teksta koristeći Excel formule, Šifriranje i dešifriranje teksta koji se sastoji od višestrukih znakova/karaktera i slova, Šifriranje teksta uz dodavanje grupe slova uz svako slovo ili znak-karakter

Kako koristiti šifriranje, kriptografiju i enkripciju u Excelu




sponzor



Enigma stroj za šifriranje

Vjerujem da ste čuli za ENIGMU tj. uređaj pomoću kojeg se može šifrirati poruka ili tekst. Izraditi vrhunski stroj za šifriranje poruka nije teško za stručnjake koji se bave kriptografijom i enkripcijom. Također postoje stručnjaci koji se bave razbijanjem koda tj. dešifriranjem poruke. ENIGMA je jedan od uređaja koji je izrađen u svrhu šifriranja poruka koje je teško dešifrirati. Potaknut jednom TV emisijom o Enigma stroju kao i serijom TV emisija o špijunskim porukama između Francuske i Engleske u "Viktorijansko doba" zanimljivom idejom mi se učinilo probati izraditi jednostavan način kako enkriptirati ili šifrirati slova u Excelu. Uzmimo na primjer da želite šifrirati vaše lozinke koje koristite za pristup emailu ili forumima, facebook, instagramu, whatsup aplikacijama i slično.

Priprema rasporeda slova i znakova-karaktera za enkripciju

Za ovaj Excel tutorijal pokazati ću "jednostavan primjer" kako šifrirati i dešifrirati određeni tekst. Sam postupak enkripcije i dekripcije sastoji se iz dva dijela. "Šifriranje" i "Dešifriranje" slova. Na slici ispod uočite kako izgleda raspored slova i karaktera/znakova pomoću kojih sam uradio šifriranje i dešifriranje teksta/slova.

Slika 1

Redoslijed slova i znakova za šifriranje teksta

Na slici iznad možete vidjeti dva para raspona ćelija koji se odnose na enkripciju i dekripciju. Na ovaj način sam dva puta šifrirao slova/tekst. Prvo sam otvoreni tekst šifrirao sa slovima iz stupaca 'A:C' pa poslije šifrirao slovima iz stupaca 'I:K'. Dakle dva puta sam ponovio šifriranje (Encription 1 => Encription 2). Također uočite dva različita rasporeda slova i znakova u stupcima 'B,F/J,N'. Dakle ovo je važno jer onaj tko želi probiti šifru trebao bi znati ova dva rasporeda. Svako slovo i karakter treba imati postavljen apostrof ispred!

Slijedeće formule su postavljene u ćelijama:

U 'A3' ćeliju postavljena je formula:
=ROW(A1)-1

U 'A4' ćeliju postavljena je formula: (ova formula kopirana je do 'A6' ćelije)
=A3+1

U 'A7' ćeliju postavljena je formula:
=C3

U 'A8' ćeliju postavljena je formula: (ova formula kopirana je do zadnjeg reda)
=A7+1

U 'C3' ćeliju postavljena je formula: (ova formula povlači podatak iz 'R2' ćelije a to je broj koji određuje startni broj)
=$R$2

U 'C4' ćeliju postavljena je formula: (ova formula kopirana je do zadnjeg reda)
=C3+1

U ostalim stupcima formule su iste samo se referenciraju na druge ćelije (sve možete vidjeti u Excel datoteci u prilogu)

Kada jednom postavite startnu poziciju za eventualni raspored slova i znakova u srednjem stupcu možete si pripremiti unaprijed već određeni raspored kao na slici ispod (ovaj raspored može biti na nekom drugom radnom listu).

Slika 2

raspored slova i znakova za kriptografiju ili šifriranje

Šifriranje otvorenog teksta u Excelu

Na 'Slika 3' ispod uočite dijelove koje sam upotrijebio za šifriranje i dešifriranje teksta. U 'R2' i 'S2' ćelijama nalaze se dva broja. Na početku ovog tutorijala naglasio sam da na ovaj način postavljamo startni broj. Broj iz 'R2' ćelije reflektira se u 'C3', 'E3', 'A7' i 'G7' ćelije. Broj iz 'S2' ćelije reflektira se u 'K3', 'M3', 'I7' i 'O7' ćelije (vidi Sliku 1).

U 'Z2' i 'AA2' nalaze se identični brojevi kao kontrolni ključevi za jednu od formula koju možete pronaći u daljnjem tekstu ovog tutorijala (nju ću opisati kasnije).

U 'R5:AE5' ćelijama nalaze se naša slova koja želimo kodirati tj. šifrirati

Slika 3

šifriranje i kriptografija slova u Excelu

Formule za šifriranje i kodiranje teksta u Excelu (Encripted Text)

U 'R9:AE9' ćelijama nalaze se formule pomoću kojih šifriramo svako slovo iz petog reda. Dakle 'W' slovo je šifrirano u 'A' slovo, i tako redom.

Formula u 'R9' ćeliji je slijedeća: (ova formula mora biti postavljena u parni stupac i ovu formulu kopirajte u desnu stranu)
=IF(ISEVEN(COLUMN(R1))=TRUE;IF(R5="";"";VLOOKUP(VLOOKUP(R5;$B$3:$C$45;2;FALSE);$A$3:$B$45;2;FALSE));
IF(R5="";"";VLOOKUP(VLOOKUP(R5;$J$3:$K$45;2;FALSE);$I$3:$J$45;2;FALSE)))

Formula iznad može biti kreirana sa imenovanim rasponima ćelija, pa ona izgleda ovako kao u 'R11' ćeliji:
=IF(ISEVEN(COLUMN(R1))=TRUE;IF(R5="";"";VLOOKUP(VLOOKUP(R5;encription1Alphabet;2;FALSE);encription1Numbers;2;
FALSE));IF(R5="";"";VLOOKUP(VLOOKUP(R5;encription2Alphabet;2;FALSE);encription2Numbers;2;FALSE)))

Formule za dešifriranje i dekodiranje teksta u Excel (Decripted Text)

U 'R14:AE14' ćelijama nalaze se formule pomoću kojih dešifriramo svako slovo iz šifriranog teksta. Dakle 'A' slovo je dešifrirano u 'W' u slovo, i tako redom. Ove formule trebaju biti vaša tajna (ili kreirajte neku drugu formulu koja će moći koristiti vaš tajni ključ za dešifriranje).

Formula u 'R14' ćeliji je slijedeća: (ova formula mora biti postavljena u parni stupac i ovu formulu kopirajte u desnu stranu).
=IF(ISEVEN(COLUMN(R1))=TRUE;IF(R9="";"";VLOOKUP(VLOOKUP(R9;$F$3:$G$45;2;FALSE);$E$3:$F$45;2;FALSE));IF(R9="";
"";VLOOKUP(VLOOKUP(R9;$N$3:$O$45;2;FALSE);$M$3:$N$45;2;FALSE)))

Formula iznad može biti kreirana sa imenovanim rasponima ćelija, pa ona izgleda ovako kao u 'R16' ćeliji: (ovu formulu kopirajte u desnu stranu).
=IF(ISEVEN(COLUMN(R1))=TRUE;IF(R9="";"";VLOOKUP(VLOOKUP(R9;decription1Alphabet;2;FALSE);decription1Numbers;2;
FALSE));IF(R9="";"";VLOOKUP(VLOOKUP(R9;decription2Alphabet;2;FALSE);decription2Numbers;2;FALSE)))

Formula u 'R18' ćeliji vezana je za 'Z2' i 'AA2'. U prethodnom tekstu spomenuo sam ove dvije ćelije. One su kontrolni ključ koji je potrebno znati da bi se ispravno dešifrirao tekst. Zbroj ova dva broja treba biti jednak zbroju brojeva u 'R2 i S2' ćelijama. Formulu kopirajte u desnu stranu.
=IFERROR(IF(AND($R$2=$Z$2;$S$2=$AA$2;ISEVEN(COLUMN(R1))=TRUE);VLOOKUP(VLOOKUP(R9;$F$3:$G$45;2;FALSE);
$E$3:$F$45;2;FALSE);VLOOKUP(VLOOKUP(R9;$N$3:$O$45;2;FALSE);$M$3:$N$45;2;FALSE));"")

Šifriranje teksta uz dodavanje grupe slova uz svako slovo ili znak-karakter

Ako želimo zakomplicirati dešifriranje "potencijalom hakeru" ili nepoželjnoj osobi tada možemo povećati zaštitu šifriranja.
Na slici 4 uočite stupac 'AI' i 'AJ'. Ovo su pomoćni stupci u kojima sam postavio random slova u grupe od četiri znaka/slova. Naravno vi možete postaviti više slova u svakoj grupi.

Također uočite 'AL2:AY2' ćelije. U ovom rasponu ćelija nalaze se moji tajni brojevi sa točno određenim slijedom. Oni su ključ šifriranja teksta u petom redu ispod.

Encripted Text 2

U 'AL5' ćeliji nalazi se formula: (ovu formulu kopirajte u desnu stranu)
=VLOOKUP(AL2;$AI$1:$AJ$43;2;FALSE)&R9
Ova Vlookup jednostavna formula traži podatak iz 'AL2' ćelije u rasponu ćelija pomoćnih stupaca, vraća određenu grupu slova i nju spaja sa šifriranim slovom iz 'R9' ćelije. Tako smo dobili grupe od 5 slova/znakova. U ovom slučaju šifrirano slovo dodano je na kraj svake grupe od 4 slova. Vi možete kombinacijom vaših formula kreirati jednu formulu koja će šifrirano slovo smjestiti na neku drugu poziciju u grupu.

Slika 4

Šifriranje teksta uz dodavanje grupe slova uz svako slovo ili znak-karakter

Dectipted Text 2

Za dešifriranje u slučaju kada imamo grupe slova/znakova možemo koristiti slijedeću formulu u 'AL15' ćeliji: (ovu formulu kopirajte u desnu stranu).
=IF(ISEVEN(COLUMN(AL1))=TRUE;IF(AL5="";"";VLOOKUP(VLOOKUP(IF(LEN(AL5)=5;RIGHT(AL5;1);"");$F$3:$G$45;2;FALSE);
$E$3:$F$45;2;FALSE)); IF(IF(LEN(AL5)=5;RIGHT(AL5;1);"")="";"";VLOOKUP(VLOOKUP(IF(LEN(AL5)=5;RIGHT(AL5;1);"");
$N$3:$O$45;2;FALSE); $M$3:$N$45;2;FALSE)))

Formula u 'AL17' ćeliji vezana je za "Control Code Key" u ćelijama 'R2, S2, Z2 i AA2'.
=IFERROR(IF(AND($R$2=$Z$2;$S$2=$AA$2;ISEVEN(COLUMN(R1))=TRUE);VLOOKUP(VLOOKUP(IF(LEN(AL5)=5;RIGHT(AL5;1);"");
$F$3:$G$45;2;FALSE );$E$3:$F$45;2;FALSE);VLOOKUP(VLOOKUP(IF(LEN(AL5)=5;RIGHT(AL5;1);"");$N$3:$O$45;2;FALSE);
$M$3:$N$45;2;FALSE));"")


Šifriranje i dešifriranje teksta koji se sastoji od višestrukih znakova/karaktera i slova

U slijedećem slučaju imamo šifrirani tekst sa višestrukim slovima i znakovima/karakterima (slika 5). Za ovakvo šifriranje koristimo pomoćni stupac kao u prethodnom primjeru. S obzirom da je pomoćni stupac jedan od tajnih ključeva za kriptografiju ili šifriranje samo mi znamo da je svako peto slovo naše ključno šifrirano slovo što možemo vidjeti u rezultatima iz petog reda.

Encripted Text 2a

Formula u 'AL24' ćeliji: (formula spaja grupe od 5 slova/karaktera u jedan višestruki niz slova)
=SUBSTITUTE(TRIM(AL5&" "&AM5&" "&AN5&" "&AO5&" "&AP5&" "&AQ5&" "&AR5&" "&AS5&" "&AT5&" "&AU5&" "&AV5&" "&AW5&" "&AX5&" "&AY5);" ";"")

Decripted Text 2a

Da bi dešifrirali tekst iz 'AL24' ćelije upotrijebio sam slijedeću formulu u 'AL28' ćeliji: (kada kopirate ovu formulu u vaš Excel, postavite je u jednu liniju).
=IF(ISEVEN(COLUMN(AL1))=TRUE;IF(MID($AL$24;COLUMN(A1)*5;1)="";"";VLOOKUP(VLOOKUP(MID($AL$24;COLUMN(A1)*5;1);
$F$3:$G$45;2;FALSE); $E$3:$F$45;2;FALSE));IF(MID($AL$24;COLUMN(A1)*5;1)="";""; VLOOKUP(VLOOKUP(MID($AL$24;
COLUMN(A1)* 5;1);$N$3:$O$45;2;FALSE);$M$3:$N$45; 2;FALSE)))

Slika 5

šifriranje teksta višestrukim nizom slova

Ako ste zaljubljenik u šifriranje i enkripciju a ovaj tutorijal vas potaknuo da se poigrate više sa šifriranjem i dešifriranjem u Excelu, na internetu postoji dosta primjera na temu šifriranja teksta. Također na nekim web stranicama možete izvršiti download Excel datoteka koje su rađene koristeći VBA makronaredbe. U ovom Excel tutorijal imate mogućnost skinuti (DOWNLOAD datoteke sa primjerom šifriranja u Excelu) na vaše računalo datoteku iz primjera koja je izrađena pomoću jednostavnih Excel formula. I na kraju zapamtite, nema 100% zaštite, svaka šifra se može probiti samo je pitanje vremena.

Budite pažljivi i pazite kome vjerujete kada pokrećete XLS ili XLSM Excel datoteke na računalu!
Ako želite pokrenuti Excel datoteku formata *.xls ili *.xlsm, a niste sigurni sadrži li dotična datoteka maliciozni VBA kod, tada pritisnite SHIFT tipku prilikom otvaranja Workbook (na taj način spriječit ćete izvođenje VBA makronaredbi).




     

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela