logotip web stranice ic.ims.hr
Home - počtna stranica  FORUM ACCESS 2003 EXCEL 2003 WORD 2003  
1 Pokretanje i zatvaranje Microsoft Excel-a 2013
2 Izgled prozora Microsoft Excela 2013
3 Alatne trake u MS Excelu 2013
4 Podešavanje Excela
5 Otvaranje nove radne knjige i radnog lista
6 Spremanje i zatvaranje Workbook u Excelu
7 Pregled radnog lista prije ispisa u Excelu 2013
8 Određivanje margina Radnog lista
9 Kreiranje Zaglavlja i Podnožja Radnog lista
10 Ispis radnog lista ili tablice ili područja u Excelu 2013
11 Kreiranje mapa u Excelu
12 Kretanje radnom tablicom u Excelu 2013
13 Označavanje ili selektiranje u Excelu
14 Operatori u Excelu
15 Kreiranje formule u Excelu
16 Uvjetno oblikovanje u Excelu 2013
17 Kako izraditi padajuću listu u Excelu - Data Validation
18 Imenovanje ćelija ili raspona podataka u excelu 2013
19 Poravnanje teksta
20 Promjena podataka i brisanje sadržaja ćelije u Excelu 2013
21 Spajanje i dijeljenje ćelija u Excelu 2013
22 Automatska ispuna - brzi unos podataka
23 Popunjavanje ćelija specijalnim znakovima i simbolima
24 Crtanje u Excelu 2013
25 Dodavanje komentara na ćelije u Excelu 2013
26 Naredbe poništi i ponovi u excelu 2013
27 Premještanje, izrezivanje i kopiranje sadržaja ćelije u Excelu 2013
28 Umetanje i brisanje Ćelija, Stupaca i Redova
29 Promjena veličine Ćelija, Stupaca i Redova u Excelu 2013
30 Umetanje slika u Excelu
31 Radnje vezane uz Radni List u Excelu 2013
32 Apsolutna i relativna adresa ćelija u Excelu
33 Izrada Grafikona u Excelu 2013
34 Oblikovanje radnih tablica u Excelu 2013
35 Sortiranje podataka u Excelu 2013
36 Filtriranje podataka u Excelu 2013
37 Kreiranje Pivot Table
38 Zamrzavanje dijela prozora radnog lista u Excelu 2013
39 Oblikovanje Datuma u Excelu 2013
40 Zaključavanje ćelija i radnog lista u Excelu 2013
41 Zaštita radne knjige u Excelu 2013
42 Greške u Excelu 2013
43 Popis svih funkcija u Excelu 2013
44 Tipkovni prečaci u Excelu (hot key, shortcut)
45 Ograničenja u Excelu 2013
46 Makronaredbe u Excelu
47 Razni primjeri u Excelu
   
1 Excel 2003 primjeri
1 Excel 2007 primjeri
1 VBA U EXCELU
   
 

MICROSOFT EXCEL 2013 tutoriali -Mjerenje količine goriva u spremniku benzinske crpke, Euro Super 95, Euro Super 98, Euro Diesel, Lož Ulje,

Automatizacija mjerenja količine tekućine u spremniku benzinske pumpe




sponzor



Kako automatski dobiti rezultate mjerenja količine goriva na osnovu vrijednosti na mjernoj letvi

U nastavku tutorijala o automatizaciji mjerenja količine goriva u spremniku u ovom dijelu prikazat ću prvu varijantu i način na koji možemo vrlo brzo dobiti rezultat za određeni uvjet a uvjet u ovom slučaju je vrijednost izmjerene visine gornje raznine goriva (benzina/dizela).

Blok šema:

Blok shema varijanta 1

Tutorijal Varijanta 1.

  1. radni list - TablicaS7 => vrijednosti proizvođača spremnika za određenu visinu mjerenja u centimetrima (desetice/jedinice)
  2. radni list - S7mm => pomoćni radni list sa kojega povlačimo određene podatke da bi dobili željeni rezultat.
  3. radni list - Korekcije => radni list na kojem se nalaze koeficijenti za korekcije pri određenoj temperaturi.
  4. radni list - Kalkulacija => na kojoj unosimo dvije osnovne vrijednosti (Temperaturu i izmjerenu visinu na mjernoj letvi), u ovoj varijanti formula povlači podatke sa pomoćnog radnog lista 'S7mm'.

Radni list 'TablicaS7' - Slika 2.

Ovaj radni list je osnova svih proračuna i izračuna količine goriva u spremniku na osnovu izmjerene visine na mjernoj letvi. Ovu tablicu isporučuje proizvođač koji je proizveo spremnik određenog oblika.

  • Oznaka 'S7' u ćeliji A1 je osobna oznaka spremnika broj 7. Dakle nemojte vezati ovu oznaku 'S7' uz nekakvu matematiku ovih proračuna. Tu sam mogao napisati i 'spremnikSedmi'.
  • U prvom stupcu tablice A2:A27 uočite brojeve 10-250. Tu su "DESETICE" za izmjerenu visinu
  • U prvom redu raspon ćelija A1:K1 (prviRedtablice) nalaze se brojevi od 1-9. To su "JEDINICE" za izmjerenu visinu. Uočite ćeliju C4 i vrijednost 1802. Ova ćelija je sjecište izmjerene visine na mjernoj letvi a u ovom slučaju je to 21 cm (20+1). Ovdje nedostaju 'milimetri', te milimetre uračunavamo pomoću formula na radnom listu 'S7mm' što ćete vidjeti u daljnjem pregledu ovog tutorijala.
  • Podaci ili vrijednosti koje se nalaze u rasponu ćelija B2:K27 su količine litara za dotičnu visinu gornje razine količine goriva u spremniku

Slika 2.

Izvorna tablica specificiranih količina u spremniku na bazi izmjerene visine goriva ili tekućine

Na ovom radnom listu korišteni su slijedeći rasponi ćelija koji su imenovani (Define Name).

  • ćelija C2 na radnom listu 'Kalkulacija' => Kalkulacija!$C$2 => imenovani naziv je 'celijaC2'
  • raspon ćelija A2:K27 na radnom listu 'TablicaS7' => TablicaS7!$A$2:$K$27 => imenovani naziv je 'tablica'
  • raspon ćelija A1:K1 na radnom listu 'TablicaS7' => TablicaS7!$A$1:$K$1 => imenovani naziv je 'prviRedtablice'

Također na radnom listu 'TablicaS7' koristio sam Conditional Formatting da bi označio tj. obojao ćeliju iz koje formula na radnom listu 'Kalkulacija' u ćeliji 'C2' povlači vrijednost za izmjerenu visinu. Formula za CF primjenjena je na raspon ćelija B2:K27 a formula je slijedeća:

- Formula za CF koja koristi imenovane raspone ćelija

=B2=VLOOKUP(VALUE(TEXT(ROUNDDOWN(celijaC2;-1);0));tablica;MATCH(VALUE(RIGHT(TEXT(ROUNDDOWN(celijaC2;0);0);1));prviRedtablice;0);0)

- Ovdje želim napomenuti da ne možete u formuli za CF koristiti apsolutne raspone ćelija (Kalkulacija!$C$2) jer tada formula ne funkcionira. S obzirom da se ćelija C2 nalazi na drugom radnom listu 'Kalkulacija' a CF formula na dotičnom radnom listu 'TablicaS7' morate koristititi imenovanje ćelije 'celijaC2'.

Dakle formula može biti kreirana i na ovaj način (formula koristi kombinaciju imenovanih ćelija i apsolutnih adresa):

=B2=VLOOKUP(VALUE(TEXT(ROUNDDOWN(celijaC2;-1);0));TablicaS7!$A$2:$K$27;MATCH(VALUE(RIGHT(TEXT(ROUNDDOWN(celijaC2;0);0);1));TablicaS7!$A$1:$K$1;0);0)

Radni list 'S7mm' - Slika 3.

Pomoćni radni list koji služi kao baza za daljnje proračune na radnom listu 'Kalkulacija'.

Na ovom radnom listu su slijedeći rasponi ćelija koji su imenovani (Define Name).

  • raspon ćelija A3:E253 na radnom listu 'S7mm' => $A$3:$E$253 => imenovani naziv je 'litreMilimetri'

Ova tablica tj. raspon ćelija služi nam kao izvor podataka za povlačenje određenih podataka kada koristimo VLOOKUP ili neku drugu funkciju/formulu u proračunima tj. formulama na radnom listu 'Kalkulacija'.

Slika 3.

Excel tablica za proračun baznih vrijednosti u centimetrima uvećanih za milimetre na osnovu izmjerene visine nivoa goriva

Odmah na početku moram reći da sam i na ovom radnom listu koristio formulu za Conditional Formatting da bi označio tj. obojao ćeliju u stupcu 'D' koja sadrži identičnu vrijednost u ćeliji C2 na radnom listu 'Kalkulacija' što je u stvari rezultat količine litara za izmjerenu visinu. Formula za CF primjenjena je na raspon ćelija D3:D253

- Formula za CF koja koristi imenovane raspone ćelija

=D3=VLOOKUP(celijaC2;litreMilimetri;4;FALSE)

- Ovdje želim napomenuti da ne možete u formuli za CF koristiti apsolutne raspone ćelija (Kalkulacija!$C$2) jer tada formula ne funkcionira. S obzirom da se ćelija C2 nalazi na drugom radnom listu 'Kalkulacija' a CF formula na dotičnom radnom listu 'S7mm' morate koristititi imenovanje ćelije 'celijaC2'.

- Dakle formula može biti kreirana i na ovaj način (formula koristi kombinaciju imenovanih ćelija i apsolutnih adresa):

=D3=VLOOKUP(celijaC2;$A$3:$E$253;4;FALSE) primjenjena na cijeli raspon ćelija

To izgleda ovako kao na slici 3a ispod

Slika 3a.

New Conditional Formatting rule in Excel 2013

  • U stupcu 'E' uočite identične vrijednosti kao i u baznoj tablici proizvođača spremnika. Ja sam u stvari u ovaj stupac 'E' izvršio TRANSPOSE bazne tablice koristeći formulu i konvertirao je u jedan stupac.
  • U stupcu 'D' uočite vrijednosti koje prikazuju količinu goriva u spremniku (bazna količina iz TabliceS7 + količina za dotične milimetre iz stupca 'C'
  • U stupcu 'C' uočite identičan broj ili vrijednosti koje prikazuju "milimetre" (u ovom slučaju decimalan broj 0,6). Ovaj broj milimetara automatski se mijenja i zavisi o rezultatima formule u stupcu 'D'
  • U stupcu 'B' uočite brojeve koji su u rasponu 0 - 250. Ovi brojevi su kreirani redoslijedom i nema formule a služe nam kao izvorni podatak za daljnje proračune. Dakle ovaj stupac sadrži desetice/jedinice.
  • U stupcu 'A' uočite visine izmjerenih vrijednosti na mjernoj letvi. Vrijednosti u stupcu 'A' su u rasponu 0 - 250,9. U ovom stupcu nalazi se formula sa funkcijom Concatenate koja na osnovu stupca B i C spaja i prikazuje eventualne izmjerene visine u cm+mm a služi nam kao osnova za funciju Vlookup.

Krenuo sam sa opisom stupaca od stupca 'E'. Možda se pitate zašto? Zato jer ću koristiti VLOOKUP Excel funkciju a ostali stupci imaju dobar redoslijed zbog argumenata funkcije. Ovaj radni list nam je glavna osnova kao izvor podataka za željene rezultate. Na njemu se nalaze svi potrebni podaci za željene rezultate.

Nadalje, pokušat ću objasniti formule u stupcima

Stupac 'E'

Brojevi ili vrijednosti u stupcu 'E' su identični vrijednostima u tablici proizvođača na radnom listu 'TablicaS7'. Ja sam "Transponirao" podatke tj. posložio tablicu u jedan stupac pomoću formule. Ova formula iz ćelije E3 kopira se do E253. Također ovo Transponiranje podataka iz tablice u stupac može se izvršiti koristeći VBA makronaredbu.

- Formula za transponiranje tablice u stupac, u stupcu 'E' ćelija 'E3' koja koristi imenovane raspone ćelija

=VLOOKUP(VALUE(TEXT(ROUNDDOWN(B3;-1);0));tablica;MATCH(VALUE(RIGHT(TEXT(ROUNDDOWN(B3;0);0);1));prviRedtablice;0);0))

- Formula za transponiranje tablice u stupac, u stupcu 'E' ćelija 'E3 koja koristi apsolutne raspone ćelija

=VLOOKUP(VALUE(TEXT(ROUNDDOWN(B3;-1);0));TablicaS7!$A$2:$K$27;MATCH(VALUE(RIGHT(TEXT(ROUNDDOWN(B3;0);0);1));TablicaS7!$A$1:$K$1;0);0)

Stupac 'D'

Formula u stupcu 'D' u ćeliji 'D3' automatski proračunava količinu goriva u spremniku za izmjerenu visinu na mjernoj letvi. Korištenjem ove formule dodajemo količinu goriva koja se odnosi na 'milimetre' na mjernoj letvi. Uočite da u tablici proizvođača na radnom listu 'tablicaS7' nema vrijednosti za milimetre. Dakle kada u ćeliju 'C2' unesemo izmjerenu vrijednost 21,6 (broj koji sadrži milimetre) tada će se u stupcu 'C' pojaviti broj koji se odnosi samo na milimetre. Na slici uočite broj 6 za izmjerenu vrijednost 21,6.

Dakle formula u stupcu 'D' u ćeliji 'D3' u svom proračunu i kalkulaciju u obzir uzima vrijednosti ili podatke iz stupaca 'C' i 'E'. Rezultat ove formule je stvarana količina goriva u spremniku za izmjerenu vrijednost. U stvari ova formula dodaje količinu za milimetre na osnovnu količinu za centimetre (desetice/jedinice).

- Formula u stupcu 'D' ćelija 'D3' koja se kopira do zadnjeg reda tablice. Ova formula proračunava količinu goriva za cjelokupan broj izmjerene vrijednosti (centimetre i milimetre)

=(E4-E3)/10*C3+E3

Stupac 'C'

U stupcu 'C' u ćeliji 'C3' nalazi se formula koja izdvaja broj iza decimale izmjerene vrijednosti koju smo upisali u ćeliju 'C2' na radnom listu 'Kalkulacija'.

Nekoliko rezultata ove formule izgledaju ovako:

  • izmjerena vrijednost visine =21,6 => rezultat =6
  • izmjerena vrijednost visine =35,7 => rezultat =7
  • izmjerena vrijednost visine =110,0 => rezultat =0

- Formula u stupcu 'C' ćelija 'C3' koja se kopira do zadnjeg reda tablice. Formula korist Excel RIGHT funkciju i ugniježđenu funkciju TEXT a funkcionira tako što vrijednost u ćeliji 'Kalkulacija!$C$2' konvertira u tekst pa potom izdvaja zadnji znak u tekstualnom nizu (u ovom slučaju znamenku) ili prvi znak teksta počevši sa desne strane.

=RIGHT(TEXT(Kalkulacija!$C$2;"0,0")) ili imenovana formula =RIGHT(TEXT(celijaC2;"0,0"))

Stupac 'B'

U stupcu B nalaze se redni brojevi od 1 do 250 počevši u ćeliji B3. Ovo su u stvari svi centimetri (desetice i jedinice) poredane uzlazno i identične su kombinacijama sa deseticama i jedinicama iz tablice proizvođača na radnom listu 'TablicaS7'. Ovdje nema formule. Brojeve u ovom stupcu koristimo u formuli stupca 'A'

Stupac 'A'

U ovom stupcu nalazi se formula koja spaja vrijednosti centimetara (desetice i jedinice) sa decimalama vrijednosti milimetara. Rezulatat ove formule identičan je upisanoj vrijednosti u ćeliji 'C2 na radnom listu 'Kalkulacija'') a koristimo ga za upotrebu funkcije VLOOKUP.

- Formula u stupcu 'A' ćelija 'A3' koja se kopira do zadnjeg reda tablice.

=VALUE(B3&","&C3) ili koristeći CONCATENATE Excel funkciju =CONCATENATE(B9;",";C9)

Radni list 'Korekcije' - Slika 4.

Na radnom listu 'Korekcije' nalaze se temperature i koeficijenti za korekciju u odnosu na pripadajuću temperaturu za određeni tip goriva.

Rani list 'Korekcije' sadrži temperature i koeficijente za određenu temperaturu.

  • U stupcu 'A' je raspon ćelija A2:A102 (temperatura) koristio sam za padajući izbornik (Drop-Down Menu) na radnom listu 'Kalkulacija' u stupcu 'B' što se vidi u ćeliji B2. Ovaj imenovani naziv 'temperatura' koristi se u Data Validation na radnom listu 'Kalkulacija' u ćelijama B2:B5. Pretpostavljam da i ove vrijednosti isporučuje proizvođač spremnika goriva / tekućine. Raspon temperatura u stupcu 'A' je od -15 °C do +35 °C sa razmakom od 0,5 °C.
  • U stupcu 'B' uočite koeficijente korekcije za određenu temperaturu. Pretpostavljam da ove koeficijente također izdaje proizvođač spremnika.

Ja sam u ovom tutorijalu koristio samo E. Super 95.
Na ovom radnom listu korišteni su slijedeći rasponi ćelija koji su imenovani (Define Name).

  • raspon ćelija A2:A102 na radnom listu 'Korekcije' => Korekcije!$A$2:$A$102 => imenovani naziv je 'temperature'
  • raspon ćelija A2:B102 na radnom listu 'Korekcije' => Korekcije!$A$2:$B$102 => imenovani naziv je 'korekcijaSuper95'

Nadalje uočite i ostale koeficijente za ostale naftne derivate (Euro Super 98, Euro Dizel, Lož Ulje)

Slika 4.

Koeficijenti za određenu temperaturu

Iz ovog radnog lista VLOOKUP formule uzimaju koeficijent korekcije za postavljenu temperaturu u ćeliji B2 na radnom listu 'Kalkulacija'.

Na ovom radnom listu nema formula. Postoji samo formula za Conditional Formatting da bi označio tj. obojao ćeliju u stupcu 'B' koja sadrži identičnu vrijednost u ćeliji B2 na radnom listu 'Kalkulacija' što je u stvari temperatura u trenutku mjerenja

- Formula za CF ili Conditional Formatting koja koristi imenovane raspone ćelija

=$B2=VLOOKUP(cellB2;korekcijaSuper95;2;FALSE)

- Ovdje želim napomenuti da ne možete u formuli za CF koristiti apsolutne raspone ćelija (Kalkulacija!$B$2) jer tada formula ne funkcionira. S obzirom da se ćelija B2 nalazi na drugom radnom listu 'Kalkulacija' a CF formula na dotičnom radnom listu 'Korekcije' morate koristititi imenovanje ćelije 'cellB2'.

- Dakle formula može biti kreirana i na ovaj način (formula koristi kombinaciju imenovanih ćelija i apsolutnih adresa):

=$B2=VLOOKUP(cellB2;Korekcije!$A$2:$B$102;2;FALSE) . To izgleda ovako kao na slici 3a uz ovu formulu

Radni list 'Kalkulacija' - Slika 1.

Ovaj radni list 'Kalkulacija' je naš aktivni radni list na kojem unosimo neke određene vrijednosti i automatski imamo željene rezultate. Te osnovne vrijednosti su:

  • izmjerena visina na mjernoj letvi
  • temperatura u trenutku mjerenja
  • količina litara u spremniku u odnosu na izmjerenu visinu
  • količina litara u spremniku u odnosu na izmjerenu visinu i temperaturu tokom mjerenja gdje se vrši korekcija

Mi upisujemo samo podatke u ćelije stupca B i C, u ovom slučaju B2 i C2. U ćelijama stupaca D i E, Excel automatski izračunava potrebne vrijednosti količine litara goriva na osnovu uvjeta u B2 i C2 ćelijama.

Ćelija B2 (ova ćelija imenovana je nazivom 'cellB2') vezana je za proračun u ćeliji E2 istog radnog lista
Ćelija C2 (ova ćelija imenovana je nazivom 'celijaC2') vezana je za proračun u ćeliji D2 istog radnog lista

Slika 1.

Mjerenje količine goriva u spremniku benzinske crpke

  • U stupcu 'A' nalazi se popis naftnih derivata koji se nalaze u spremnicima za koje trebamo izmjeriti količinu zapremine u litrama (Euro Super 95, Euro Super 98, Euro Diesel, Lož Ulje). U ovom tutorijalu obrađen je samo prvi naftni derivat 'Euro Super 95' za koji je primjenjena tablica baznih količine zapremine goriva na osnovu izmjerene visine na mjernoj letvi (više o dotičnoj tablici na slici 2 na radnom listu 'TablicaS7').
  • U stupcu 'B' uočite padajući izbornik na kojem se nalazi popis eventualne temperature u trenutku mjerenja (ovaj popis ima raspon od -15 °C do +35 °C. Ova temperatura važna je za izračun količine goriva sa korekcijama. Ovu temperaturu biramo iz padajućeg izbornika (Drop-Down Menu) koji smo kreirali u Data Validation kao na slici ispod. Uočite da smo ovdje za Source: upisali imenovani raspon A2:A102 na radnom listu 'Korekcije' a njega smo imenovali nazivom 'temperature'. Pogledajte opis iznad za Sheet 'Korekcije'.
    provjera valjanosti podataka u Excelu 2013
  • U stupcu 'C' vrijednost koja je u stvari visina na mjernoj letvi nakon mjerenja količine goriva u spremniku. U ovom tutorijalu ćeliju 'C2' ja sam imenovao nazivom "celijaC2". U početku ovog tutorijala radnog lista 'TablicaS7' vidjeli ste da smo koristili Conditional Formatting. Zbog CF je važno ovo imenovanje ćelije 'C2'.
  • U stupcu 'D' uočite rezultat količine goriva koju je Excel proračunao s obzirom na izmjerenu visinu iz stupca 'C' i bazne tablice proizvođača na radnom listu 'TablicaS7' ili tablice podataka na pomoćnom radnom listu 'S7mm'.
  • U stupcu 'E' uočite kao rezultat količinu goriva u spremniku na osnovu temperature i koeficijenta korekcije za dotičnu temperaturu.

I na kraju, željene rezultate dobivamo funkcijom VLOOKUP.

Ćelija D2.

- Formula u stupcu 'D' ćelija 'D2' koja koristi imenovane raspone ćelija

=VLOOKUP(C2;litreMilimetri;4;FALSE)

- Formula u stupcu 'D' ćelija 'D2' koja koristi apsolutne raspone ćelija

=VLOOKUP(C2;S7mm!$A$3:$E$253;4;FALSE)

Ova formula kao izvornu bazu koristi podatke na radnom listu 'S7mm' a traži podatak koji je pripadajući uvjetu u C2. U ovom slučaju to izgleda ovako:

Formula pronalazi uvjet iz C2 tj. vrijednost 21,6 u stupcu 'A' raspona ćelija '$A$3:$E$253' u ćeliji 'A24' na radnom listu 'S7mm' i vraća vrijednost iz istog reda a iz stupca 4 (četvrti stupac raspona je stupac 'D'), a to je broj 1886.

Do ovog broja 1886 došli smo matematikom pomoću ove formule u stupcu 'D' radnog lista 'S7mm' =(E25-E24)/10*C24+E24 koju sam već pojasnio na radnom listu 'S7mm' gore iznad.

sponzor


Ćelija E2.

- Formula u stupcu 'E' ćelija 'E2' koja koristi imenovane raspone ćelija

=VLOOKUP(B2;korekcijaSuper95;2;FALSE)*D2

- Formula u stupcu 'E' ćelija 'E2' koja koristi apsolutne raspone ćelija

=VLOOKUP(B2;Korekcije!$A$2:$B$102;2;FALSE)

Ova formula kao izvornu bazu koristi podatke na radnom listu 'Korekcije' a traži podatak koji je pripadajući uvjetu u B2. U ovom slučaju to izgleda ovako:

Formula pronalazi uvjet iz B2 tj. vrijednost temperature od 5 °C u stupcu 'A' raspona ćelija '$A$2:$B$102' i pronađe ga u ćeliji 'A42' na radnom listu 'Korekcije' i vraća vrijednost iz istog reda ali iz stupca 2 (drugi stupac raspona je stupac 'B'), a to je broj tj. koeficijent 1,0118. Rezultat je 1908,25 litara

Do ovog broja 1908,25 došli smo matematikom tako što smo pronađeni koeficijent pomnožili se sa brojem u C2 ćeliji (1886*1,0118=1908,25 litara).

I na kraju pogled na Name Manager dotične workbook

Name Manager u Excelu

Nadam se da sam uspio objasniti Varijantu 1. :-)
Tutorial Varijantu 2. pogledajte na slijedećem linku klikom na Next button.




  prethodna stranica slijedeća stranica

sponzor



COPYRIGHT © - 2005 - 2020 IvanC - Sva prava pridržana - Ova web domena/web stranica koristi cookies.
Prema međunarodnom zakonu o autorskom djelu zabranjeno je kopiranje, reproduciranje, prosljeđivanje i publiciranje cijelog sadržaja ili bilo kojeg njegova dijela